{Change Comments ***********************************************************}
{5/5/89
Copied & modified: Fanuc 10T-MS [+] L004.53
For: Warman
Machine has a Tool Setter to automaticly load geometry offsets.
Deleted Home from FirstOperation and NewTool.
JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/17/90, Updated: Fanuc 10T HS TPS L100.56 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{4/23/91
Modified: Fanuc 10T HS TPS L100.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}
{5/10/91
Modified: Fanuc 10T HS TPS L100.80
Added NewHome & FirstHome, mistakenly taken out during last update.
Jim Radcliffe}
{08/05/91
Updated: Fanuc 10T HS TPS L100.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}
{10/24/91
Updated: Fanuc 10T HS TPS L100.82
For: Warman Industries
Changed the Feed in the ODApproachSP,IDApproachSP, and FaceApproachSP to a Rapid,
and put the Feed and FeedRate on the following line in all three approaches.
Kim Michelman}
{9/13/95, Updated Fanuc 10T HS TPS L100.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}
{3/7/96,
Initial: Fanuc 10T HS TPS L100.85
Created: Fanuc 10T HS TPS LXXX.85
For: HoseMaster
Added Support for a Bar Puller (Must use custom Bar Pull MDD), support for parts catcher on cutoff routines, and GearRange.
Added safety start block to all operations as per instructions from Steve Thomas. Changed Tool Change to 'M48', changed
preset to 'G92', Changed tool offset cancel to 'T0000', returns to home before every tool change. MPK}
{3/11/96,
Initial: Fanuc 10T HS 2X [HM] L431.85
Created: Fanuc 10T HS 2X [HM] L431.85.1
Deleted GearRange @ SameTool, Changed Line #s at each new tool to match tool#, turned coolant off before
tool changes, added M76 before bar pull routine, changed form to reverse spindle directions, MPK}
{3/12/96,
Initial: Fanuc 10T HS 2X [HM] L431.85.1
Created: Fanuc 10T HS 2X [HM] L431.85.2
Changed X approach move for bar pull to the stock value plus 2 as per Steve Thomas, MPK}
{3/14/96,
Initial: Fanuc 10T HS 2X [HM] L431.85.2
Created: Fanuc 10T HS 2X [HM] L431.85.3
Added Block delete with move to XSP and Z 1. at first operation and noew tool before approach, MPK}
{4/1/96,
Initial: Fanuc 10T HS 2X [HM] L431.85.3
Created: Fanuc 10T HS 2X [HM] L431.85.4
Changed backslash for block delete to forward slash, MPK}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,8) {To accomodate line numbers matching tool number, .85.1, MPK}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(CalcZSurf#,2)
FORMAT(ZDepth#,2)
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN
ApproachSP:
IF ApproachFace?
IF NOT FIStopRO? {Bar Pull}
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN
AppMove:
StockOff ThisOpEntryZCP OpToolID LatheOffset CoolOn
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
IF FIStopRO? {Bar Pull}
SeqLabC 'X' ADD# Num#('2') XStockMax# StockOnNoCan 'Z' ZDepth# OpToolID LatheOffset EOL {XCP}
SeqLabC Feed XSP 'F50.0' EOL
ELSE
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
END
ApproachSP
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
'N' Tool# LatheOffset 'M76' EOL
SeqLabC Rapid AbsorInc
IF FIStopRO?
'G54G20G94' EOL
ELSE
'G54G20G95' EOL
END
SeqLabC FirstHome 'T0000' EOL {Cancel Tool Offset}
IF NOT FIStopRO?
SeqLabC GearRange EOL
SeqLabC ToolChng OpToolID '00' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
SpinOn EOL
ELSE
SeqLabC ToolChng OpToolID '00' EOL
END
SeqLabC '/' XSP 'Z1.' EOL
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
IF LAST NOT FIStopRO? {Bar Pull}
SeqLabC LAST OpExitZCPC EOL
END
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome 'T0000' CoolOff EOL {Cancel Tool Offset}
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation}
DoOpComments
DoPostScript
IF NOT FIStopRO?
'N' Tool# LatheOffset 'M76' EOL
SeqLabC Rapid AbsorInc 'G54G20G95' EOL
SeqLabC FirstHome 'T0000' EOL {Cancel Tool Offset}
SeqLabC GearRange EOL
SeqLabC ToolChng OpToolID '00' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1 SpinOn EOL
ELSE
SeqLabC CSSOff 'G97' Speed OpToolID SpinOn EOL
END
SeqLabC '/' XSP 'Z1.' EOL
Approach
ELSE {Bar Pull}
SeqLabC SpinOff EOL
'N' Tool# LatheOffset 'M76' EOL
SeqLabC Rapid AbsOrInc 'G54G20G94' EOL
SeqLabC FirstHome 'T0000' EOL {Cancel Tool Offset}
SeqLabC ToolChng OpToolID '00' EOL
Approach
END
ELSE
IF SameTool? {.62}
{Start new Operation}
StockOff
DoOpComments
IF CoolOff? AND NOT LAST CoolOff?
SeqLabC CoolOff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CutOff?
SeqLabC 'M27' EOL {Brings down part catcher}
END
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead 'A' InFeedAngle# EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
IF FIStopRO? {Bar Pull}
SeqLabC 'M74' EOL {Open Chuck}
SeqLabC 'Z' CalcZSurf# FeedRate EOL
SeqLabC 'M73' EOL {Close Chuck}
SeqLabC OpExitXCPC FeedRate EOL
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
IF CutOff?
SeqLabC 'M28' EOL {Retracts part catcher}
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
IF NOT FIStopRO? {Bar Pull}
SeqLabC OpExitZCPC EOL
END
DoEndOpPS
IF NOT FIStopRO?
SeqLabC CoolOff EOL
END
IF ConstantSurfaceFeed?
IF NOT FIStopRO?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
END
SeqLabC FirstHome 'T0000' EOL {Cancel Tool Offset}
SeqLabC ProgStop EOL
IF NOT FIStopRO?
SeqLabC SpinOff EOL
ELSE
'M99'
EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 10T HS [KMT] L759 85Fanuc 10T HS TPS L100 85 1Fanuc 10T Miyano JNC 60 L228 85Fanuc 10T HS TS LTM L262 82 2Fanuc 10T MS AL2 [HS] L484 85 7Fanuc 6T HS [CSD] L208 85 2Fanuc 10T MS [PT] L703 85 1Fanuc 10T Mazak QT L088 85Fanuc 10T [TK] L758 85Fanuc 10T Cincom F20 L527 85 1Fanuc 10T MS [ ] L004 85Fanuc 10T MS [BMR] L768 85Fanuc 10T MS [ TPM] L455 85Fanuc 10T MS [ CES] L107 85Fanuc 10T MS [AMF] L424 85 1więcej podobnych podstron