{Change Comments ***********************************************************}

{8/17/89
Copied & modified: Fadal [CRC at CP2] M111.57
For: Cinema Products.
Added SepSub stuff.
JR}

{9/29/89
Modified: Fadal (w/SepSub) M189.61
For: Gibbs & Associates
Changed Subroutine #'s to begin with 'L100', and increment by 100.
Changed all occurances of NewProg to TagInc.
Changed SubIDF to literal 'L' Tag# '00'.
Changed Subroutine calls to 'L1nn' where nn is Repeats for 'L100'.
Changed CallLab to literal 'L' Tag#.
Added PostScript.
JR}

{1/5/90
Updated: Fadal (w/SepSub) M189.63, to .69 format.
JR}

{3/23/90, changed G to E in WFOStuff sub, 15000 max RPM, JR}
{5/9/90, Updated to Version 3.2 per Fanuc 6M M001.72 Format, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{8/24/90
Modified: Fadal (w/SepSub) M189.73
For: Gibbs & Associates
Machine: Unknown
Control: Fadal
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
Corrected AutoCycle SP and EP Status Record errors.
DWB}

{4/3/91
Modified: Fadal (w/SepSub) M189.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/15/92
Modified: Fadal (w/SepSub) M189.79
For: JPL
Changes made per conversations with JPL.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Changed the Strings in the Mach Spec. for R-Format Arcs to output 'R0' to ensure a '0' output.
KLM}

{1/20/93
Modified: Fadal (w/SepSub) M189.81.1
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
DWB}

{8/16/93
Copied & modified: Fadal (w/SepSub) M189.81.2
For: Gibbs & Associates
Changed CRCOn from CP2 to after Zin, using standard milling & ToolPath stuff now!
Jim Radcliffe}

{* 11/3/93 [cwh]
Modeified: Fadal [JPL] M189.81.2
To: Fadal [JPL] M189.81.3
For: Gibbs and Associates

Modified the form so that it could be used with the 32MP and 32MPOL
versions of Catalyst ( Virtual ).
*}

{4/14/94
Modified: Fadal [JPL] M189.81.3
For: JPL
Versions: ncCad 4.32.03/ncCAM 4.32.03/ncPost 4.32.03/Compost 4.21.20
Changes made per Darrol Houser at JPL
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Changed MoveSXYC to MoveSXYZC for variable Drilling Depths at ToolPath PointFeat.
DWB}

{11/3/94
Modified: Fadal [JPL] M189.81.4
For: JPL
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Versions: Catalyst v2.14.06C/Compost 4.21.23
Changes made per Darrol Houser at JPL.
Added support of Virtual Positive Approach for Canned Drilling Cycles.
Positive Approach is tested using IF Pulse? PostScript Command.
Code was taken from changes made on 3/8/93 to CICVIS1 M610.81.2 by Charles Haden.
Added literal 'M46' block prior to DrillCP block at IF Drilling.
Added literal 'M47' block after 'G80' block at IF Drilling.
Modified CutterRadiusCompensation.
Customer requested that CRCOn be output prior to EntryMove and CRCOff after ExitMove.
Deleted CkCRC sub and calls to same at StdLine sub.
Replaced LineFeat handling with call to StdLine sub at ToolPath LineFeat.
Deleted CRCOffC at FinishSub1 sub.
Deleted CRCOffC for LastFeat AutoCycle at ToolPath RapidFeat.
Deleted CRCOffC at ZCP3 at end of IF Milling.
Added CRCOnC to StrtPos block at FirstOperation, NewTool and SameTool.
Added CRCOffC to CoolOff block at NewTool, SameTool and end of Prog.
DWB}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{8/6/96,
Initial: Fadal [JPL] M189.81.5
Created: Fadal Format 1 [C-P] Mxxx.89
Updated to .89 format
Changed to use program# instead of Tag# for subroutine #s
Changed CRC handling to match M001.
MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.###;0'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(Repeats#,7)
FORMAT(Parts#,7)
FORMAT(CallMasterNum#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
SeqLab '* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
SeqLab '* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLab SubIDF EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLab CallLab Recall# Num#('10') EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC EOL
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab SetWFO EOL
SeqLab CallLab OnePart EOL
IncWFO
NextWFO
ELSE
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLab CallLab Recall# Num#('10') EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
SeqLab WFO1 EOL
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
SetFlag('5')
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab CallLab OnePart EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRateC EOL
DecelMove2
END
SeqLab FormatLine DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
IF LastFeat?
SeqLab CRCOffC EOL
END
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqLab 'E' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqLab 'E' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab CallLab '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLab Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab CallLab '01' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('15000')
SetMaxFeed('500')
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('5') {True = need CRCOffset }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLab 'O' Program#
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
SetProgNum('0')
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
SeqLab '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
SeqLab '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLab '* FIRST TOOL IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
WFOStuff
SeqLab Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos EOL
SeqLab OfstOn EOL
SeqLab CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff SpinOff EOL
SeqLab 'G28' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLab AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END

{Start new Operation}

SeqLab OpToolID EOL
SeqLab ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
SeqLab Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos EOL
SeqLab OfstOn EOL
SeqLab CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab CoolOff SpinOff EOL
SeqLab 'G28' EOL
SeqLab 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab Speed SpinOn EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos EOL
SeqLab OfstOn EOL
SeqLab CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset?
SeqLab 'G28' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqLab OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLab FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab AbsOrInc Rapid StrtPos EOL
END
IF Pulse?
SeqLab 'M46' EOL { Positive Approach Mode On }
END
SeqLab DrillCP EOL
GetCycle
SeqLab Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
FadalTapF FadalTapQ
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLab 'L' CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab CallLab '01' EOL
StartSub
ToolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab Rapid 'G80' ZCP3C EOL
IF PosApproach?
SeqLab 'M47' EOL { Positive Approach Mode Off }
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab AbsOrInc Rapid FirstHome SpinOff EOL
ELSE
SeqLab SpinOff EOL
END
IF ProgStop?
SeqLab 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab 'G28' EOL
SeqLab ProgStop EOL
SeqLab UnTool EOL
SeqLab ToolChng EOL
SeqLab 'E0' EOL
SeqLab EOP EOL
EndSubs
Post
EOR EOL
'BYE' EOL
Close
ReSeq
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END


Wyszukiwarka

Podobne podstrony:
Fadal Format 2 [E] M585 89
Fadal Format 2 [MM] MW60 89
Fadal Format 2 [PEP] M116 89 1
Fadal Format 2 [HM] MV16 89 1m
Fadal Format 1 [6D] MT01 89
Fadal Format 1 [PE] NMU96 89
Fadal Format 1 [SMF] M636 89 4
Fadal Format 2 [RP] MX47 89
Fadal Format 1 LH AI MV41 89 1
Fadal Format 1 WPG75 M986 89 1
Fadal Format 2 [LM] MV11 89 4
Fadal Format 1 [GTR] MW22 89
Fadal Format 1 [BA] M161 89 1
Fadal Format 1 [SM] MT74 89

więcej podobnych podstron