{Change Comments ***********************************************************}
{ 2/1/89
Copied & modified: Fanuc 10T MS L001.57 for Angelus Can.
Added GearRange. Format arcs with R. New CheckOffset.
Minor change to operation start-up blocks & end of program.
Jim Radcliffe}
{3/16/89
Modified; Fanuc 10T MS (-AG) L092.55, for Angelus Can
Added tapping operation. Added PostScript codes.
Jim Radcliffe}
{4/20/89
Modified; Fanuc 10T MS (-AG) L092.56, for Angelus Can
Moved 'LOfstOff' to line by itself after 'Home'
Jim Radcliffe}
{added PostScript comments & deleted RunTime comments 5/17/89 JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/9/90, Updated: Fanuc 10T MS (-AG) L092.59 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{11Aug97
Original: Fanuc 10T MS (-AG) L092.71.2
Original: Fanuc 10T MS (-AG) L092.85
Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format
Changed R format Maximum Arc Angle to 180.000 in MachSpec
Deleted comments {.62}, {literals}, {commands} etc.
Added CheckRapid Sub
Deleted redundant XStkLast and ZStkLast from RoughContour Canned Cycle.
Charles Winston}
{18Aug97
Original: Fanuc 10T MS (-AG) L092.85
Original: Fanuc 10T MS (-AG) L092.85.1
Deleted comments {.62}, {literals}, {commands} etc.
Changed ArcRC to ArcR in FormatArc
Charles Winston}
{8/27/98,
Initial : Fanuc 10T MS (-AG) L092.85.1
Created: Fanuc 10T MS [BMR] L768.85
Customer: B & M Racing Products, Jon Parker - 818/882-6422 ext.227
Changes to "Form":
1. Under Default Format, changed E & F to #0.####;0. and Q, R, X, Y, & Z to ###0.####;0.
2. Under Turn Rough - OD/ID, changed X Stock Left (U) and Z Stock Left (W)
Format to ###0.####;0.
3. Under Turn Rough - Face, changed X Stock Left (U) and Z Stock Left (W)
Format to ###0.####;0.
4. Under Pattern Shift, changed X Stock Left (U) and Z Stock Left (W) Format to
###0.####;0.
5. Under Threading, changed Depth of First Cut (D) Format to ##^0000 and changed
Lead of Thread Label to F. Also changed Lead of Thread (F) Format to #0.####;0.
Finish X (X), Finish Z (Z), Height of Thread (K), and X Taper (I) to ###0.####;0.
6. Under Lathe Drill Cycles, changed the two Formats to ###0.####;0.
7. Under Edit Tables, changed M41 to 1500 and M42 to 5000
Changes to "Prog":
1. Added FORMAT for SPX, SPZ, and Tag#.
2. Removed G97 output when CSS is On.
3. Changed Tool Change sequence per customer spec.
4. Changed Threading output per customer spec.
5. Changed CheckOffset sub to current standard.
6. Removed all calls to FirstFeed sub and changed to FeedrateC.
7. Changed #2 and #5 FORMATs.
8. Changed drilling dwell Label to U.
9. Removed stopping the spindle (SpinOff) IF NewGear.
JHE}
{Prog Numeric Format Definitions *******************************************}
#1 = '0.00'
#2 = '###0.####;0.' {Changed from '###.0###' - JHE}
#3 = '########;0'
#4 = '###^##0'
#5 = '#0.####;0.' {Changed from '#.######;0.' - JHE}
#6 = '###0'
#7 = '#'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(SPX#,2) {Added - JHE}
FORMAT(SPZ#,2) {Added - JHE}
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Tag#,3) {Added - JHE}
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags from last Op, .70}
ProgStopF {reset ProgStop?}
CoolOffF {reset CoolOff?}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN
ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN
AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC LOfstOff '00' {SpinOff} EOL {Removed SpinOff - JHE}
SeqLabC OpToolID LatheOffset GearRange EOL
{SeqLabC SpinOn EOL} {Removed - JHE}
ELSE
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
ELSE
IF NewGear?
{SeqLabC SpinOff EOL} {Removed - JHE}
SeqLabC GearRange EOL
{SeqLabC SpinOn EOL} {Removed - JHE}
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC 'G96' Speed EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcR
END
RETURN
FirstFeed: {Removed all calls to this sub - JHE}
{ This will force a Feedrate on FirstFeat for each operation }
IF FirstFeat? AND NOT CannedCycle? { CannedCycles force a Feedrate on the Cycle line }
Feedrate
ELSE
FeedrateC
END
RETURN
CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling? AND Dwell?
SeqLabC 'G4U' Dwell# EOL
END
IF CannedCycle?
SeqLab
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedrateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedrateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G92' MoveXC MoveZC XTapAtZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
NegSideLathe
ReverseXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' ProgramStop, PS' - EOL
' Outputs an M00 at the end of the tool.' EOL
' CoolantOff, COff -' EOL
' suppress coolant on command for current operation' EOL
END
EachOp {Start of post processing ********************************}
TagInc
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab ' '
IF ConstantSurfaceFeed?
Rapid Preset MaxRPM EOL
SeqLabC GearRange EOL
SeqLabC CSSOn 'G96' Speed SpinOn OpToolID LatheOffset EOL
ELSE
Rapid GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn OpToolID LatheOffset EOL
END
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC Rapid NewHome CoolOff EOL
ELSE
SeqLabC Rapid CoolOff EOL
END
SeqLabC LOfstOff '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation, NewTool}
DoOpComments
DoPostScript
{*** IF NewGear?
SeqLabC SpinOff EOL {Removed - JHE}
END ***}
SeqLab ' '
IF ConstantSurfaceFeed?
Rapid Preset MaxRPM EOL
SeqLabC GearRange EOL
SeqLabC CSSOn 'G96' Speed SpinOn OpToolID LatheOffset EOL
ELSE
Rapid GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn OpToolID LatheOffset EOL
END
Approach
ELSE
IF SameTool? {.62}
{Start new Operation}
DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead ToolAngle CutMethod EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC RapidC XCSP EOL
SeqLabC ZCSP EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC XCSPC ZCSPC EOL
SeqLabC LCycle ZDepth FeedRate EOL
SeqLabC SpinOff EOL
SeqLabC InverseSpinOn EOL
SeqLabC LCycle ZCSP FeedRate EOL
ELSE
SeqLabC LCycle FromCP ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLab RapidC StrtPos EOL
ToolPath
END
END
END
IF ApproachID?
SeqLabC RapidC XOpCDC EOL
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC Rapid FirstHome CoolOff EOL
ELSE
SeqLabC Rapid CoolOff EOL
END
SeqLabC OpToolID '00' SpinOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 10T MS [PT] L703 85 1Fanuc 10T MS [ TPM] L455 85Fanuc 10T MS [ CES] L107 85Fanuc 10T MS [AMF] L424 85 1Fanuc 10T MS [RHB] L458 85Fanuc 10T MS ( ót) L131 85 1Fanuc 10T MS [ BI] L441 85Fanuc 10T MS [ G54PM] L498 85 2Fanuc 10T MS ( AG) L092 85 1Fanuc 10T MS [R PSI] L648 85 1Fanuc 10T MS [R PSI] L647 85 1Fanuc 10T MS [DMW] L745 85 2więcej podobnych podstron