{Change Comments ***********************************************************}
{9/22/95, M473.81.6, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{1/17/96, Updated .85 to .86 version, MPK}
{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}
{3/12/97
Updated & Modified: GE 2000 Burgmaster M473.89
Created: GE 2000 Burgmaster M473.89.1
For: Gibbs & Associates/Seemcor
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Changes made per Pete Jackson.
Pete reported that output shifts to right and starts over never resetting itself.
Added missing EachCycle command at ZonlyRepAutoCycle sub.
Updated for Catalyst v3.30C per Fanuc 6M M001.89b Format
Added M001.14 source.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted version comments.
Deleted Flag(2) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Added SetMaxFeed(10160) for Metric VNC files.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}
{4/16/97
Initial: GE 2000 Burgmaster M473.89.1
Created: GE 2000 Burgmaster [SI]Mxxx.89
For: Seemcor Inc.
Added 'G' NewWFO# to StrtPos line in FirstOp and NewTool,
added InitWFONum to prog initialization section,
formatted NewWFO,
MPK
}
{Prog Numeric Format Definitions ****}
#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.###;0.'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Repeats#,5)
FORMAT(Parts#,5)
FORMAT(NewWFO#,5)
FORMAT(Dwell#,6)
FORMAT(Peck#,6)
FORMAT(Retract#,6)
{Prog Subroutines ****}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
WFOStuff:
{ This Post Processor does not support WorkFixtureOffsets }
RETURN
GetNewProg:
IF Flag?('3') { Don't increment the First Sub's Program# }
NewProg
ELSE
SetFlag('3')
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
SeqC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
FifthCWF
FifthCCWF
RETURN
PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
IF AbsoluteMoves?
SeqC 'B' FourthDegree# EOL
ELSE
SeqC 'A' FourthDegree# EOL
END
SeqC 'M70' EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
IF AbsoluteMoves?
SeqC 'B' FourthDegree# EOL
ELSE
SeqC 'A' FourthDegree# EOL
END
SeqC 'M70' EOL
FourthCCWF
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
IF NotEqual? Program# Program2# { Don't output at First Sub }
' ' EOL
END
SeqC '(ID, GSUB, ' Program# ')' EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC '(GSUB, ' Program# ')' 'P0=' Repeats# EOL
StartSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftR EOL
SeqC '(END, GSUB)' EOL
CloseSub
SeqC Preset UnshiftR EOL
RETURN
OpenMP:
IF EquallySpacedOffsets?
GetNewProg
SeqC '(GSUB, ' Program# ')' 'P0=' Parts# EOL
StartSub
END
RETURN
CloseMP:
IF EquallySpacedOffsets?
SeqC Preset ShiftP EOL
SeqC '(END, GSUB)' EOL
CloseSub
SeqC Preset UnshiftP EOL
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY MoveZC
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE
IF YZPlane?
MoveXC MoveY MoveZ
END
END
END
ArcIJ
RETURN
ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN
ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN
ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(GSUB, ' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC '(END, GSUB)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
GetNewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
GetNewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(GSUB, ' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC '(END, GSUB)' EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC '(GSUB, ' Program# ')' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC '(END, GSUB)' EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
GetCoolant: { PostScript Options }
IF NOT CoolOff?
IF Mist?
'M07'
ELSE
IF ThruSpin?
'M36'
ELSE
CoolOn
END
END
END
RETURN
GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
InitWFONum
SaveProgNum2
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
IF Metric?
SetMaxFeed('10160')
ELSE
SetMaxFeed('400')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('3') { 1st NewProg ByPass }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' FloodCoolat, FCool' EOL
' This is the default coolant condition.' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output main coolant selection M08.' EOL
' SetFlood, SF' EOL
' This is the default coolant condition.' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output main coolant selection M08.' EOL
' MistCoolat, MCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output spray coolant selection M07.' EOL
' SetMist, SM' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output spray coolant selection M07.' EOL
' ThruSpindleCoolant, TSCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output spindle center coolant selection M36.' EOL
' SetThruSpindle, STS' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output spindle center coolant selection M36.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify, if output is Absolute, example B12.5.' EOL
' generates a + A move of the value you specify, if output is Incremental, example A12.5.' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify, if output is Absolute, example B-22.5.' EOL
' generates a - A move of the value you specify, if output is Incremental, example A-22.5.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
OpenSub
' ' EOL
SeqC '(ID, PROG, ' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
RestoreScale
SeqC 'G80' EOL
SeqC 'G70G94' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq OpToolID ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos Speed SpinOn 'G' NewWFO# EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC AbsOrInc Rapid StrtPos Speed SpinOn EOL
END
END
ELSE
IF NewTool?
{Finish off last Operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid 'Z0.D00' EOL { OfstOff }
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
{Start new Operation}
' ' EOL
Seq OpToolID ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos Speed SpinOn 'G' NewWFO# EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC AbsOrInc Rapid StrtPos Speed SpinOn EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid 'Z0.D00' EOL { OfstOff }
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC 'M00' EOL
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid 'Z0.D00' EOL { OfstOff }
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC GetCoolant EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
GetNewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
GetNewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC GetCycle Cycle
IF RetractToCP1? {.81}
'G78'
END
StrtPos ZDepth RLevel
IF Dwell?
'P3=' Dwell#
END
IF Peck?
'P1=' Peck#
IF PeckChipBreaker?
'P4=' Retract#
ELSE
'P4=0' {full out}
END
END
FeedEnt EOL
IF CallMasterOp?
SeqC '(GSUB, ' CallMasterNum# ')' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
SetFlag('3') { 1st NewProg ByPass Drill Subs OverRide }
NewMasterProg
SeqC '(GSUB, ' Program# ')' EOL
StartSub
ToolPath
SeqC '(END, GSUB)' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid 'Z0.D00' EOL { OfstOff }
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
SeqC '(END, PROG)' EOL
ASCII('4') EOL { End of Transmission for Multiple Loads }
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
W&S 2SC GE 2000 [BD4] L773 85 1Fanuc 10M MS MVJr[SI] M916 89GE 2000 Bullard VTL L502 85GE 550 DeVlieg 4K M908 89GE 2000 Monarch M796 87GE 2000 Monarch L116 82Fagor 8025 Burg [FRB] MZ01 89GE 2000 Monarch [BK] M928 87 2GE 2000 Monarch [LBS] MU10 87GE 1050MC Mon [FD] NMT90 89 3mGE 2000 WhiteGray GT L660 85 3GE 1050MC Monarch [DTE] M204 89GE MC 2000 Excello M085 89GE MC One M682 89GE 550 Cinc M909 89więcej podobnych podstron