{Change Comments ***********************************************************}
{11/23/94
Copied: Fanuc 10T MS [-] L001.82.1b
Created: ProtoTRAK LX2 L317.82.1
For: Tower Tool
Machine:
Control: ProtoTRAK LX2
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per Mike Lapchynski and zeroxed manual.
Output is similar to modified Fanuc 6T control.
FeedRates are programmed in inches per minute, not inches per revolution.
Added ' F' MUL# SpeedRPM# FeedIPR# formula.
Added Flag(1) to support conditionality.
Control only supports G00, G01, G02 and G03 commands of the G-Code group.
Control does not support any M-Code group commands.
Deleted all Spindle and Coolant related commands.
Changed all SeqLab commands to Seq.
Added spaced to all Addresses.
Deleted all Offset related commands.
Deleted all ProgStop related commands.
Control only supports Canned Threading and Pecking Cycles.
Added Var(1) to count number of passes.
Changed NegSideLathe to PosSideLathe at setup and initializations.
Changed ReverseXZArcs to StandardXZArcs at setup and initializations.
Deleted EOR and ProgID1 at FirstOperation.
Deleted all Preset commands.
Added literal ' G20' at FirstOperation.
Deleted all Dwell Related commands.
DWB}
{6/15/95
Updated: ProtoTRAK LX2 L317.82.1
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.29
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added support for AutoFinish of non-Canned Threading Cycle.
Added FinishXDia# to FORMAT#2 at Prog Numeric Format Definitions.
Added FinishZ# to FORMAT#2 at Prog Numeric Format Definitions.
Deleted FirstMoveEPZ# from FORMAT#2 at Prog Numeric Format Definitions.
Command is not used.
Added FORMAT(MUL#,2) at non-Canned AutoFinish.
Gets reset to FORMAT(MUL#,8), for formula at GetFeedRateC sub.
Added FORMAT(FinishXDia#,2) at non-Canned AutoFinish.
Gets reset to FORMAT(FinishXDia#,7), for formula at Canned Threading.
DWB}
{6/15/95
Copied: ProtoTRAK LX2 L317.82.2
Created: ProtoTRAK LX2 [PE] L350.82.1
For: Perkin Elmer
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.29
Changes made per Tom Donaldson of Murtaugh.
Changed FORMAT for Address T from '00' to '#0' in Mach Spec Default Formats Dialog.
DWB}
{8/2/95, Updated ProtoTRAK LX2 [PE] L350.82.1 to .85 format, JR}
{8/9/95
Initial: ProtoTRAK LX2 [PE] L350.85
Created: ProtoTRAK LX2 [PE] L350.85.01
ForUser: Murtaugh / Perkin Elmer
Control: LX2
Machine: ??
Develop: ComPost 4.21.32, Virtual v.2.20
Comment: Modified per before and after edits outputs.
Added OpToolID to FirstOperation
Changed FORMAT for Address T from '#0' to '00' in Mach Spec Default Formats Dialog.
Modified Threading Canned Cycle:
Added OpToolID to Thread Cycle line.
Changed ToolAngle to ' A' InFeedAngle#
Changed FinishXDia# to a formula to output the major diameter.
Changed XatFinZ to a formula to output the major diameter.
Fixed up formatting issue with FinishXDia# as I no longer needed it.
Jim Radcliffe}
{8/16/95
Initial: ProtoTRAK LX2 [PE] L350.85.01
Created: ProtoTRAK LX2 [PE] L350.85.02
Comment: Fine turning of processor per notes supplied
Added ThreadStarts# for mutiple thread starts.
Added ASCII 10 to Line terminator in MachSpec.
This should solve the communications problem!?
Jim Radcliffe}
{9/11/95
Initial: ProtoTRAK LX2 [PE] L350.85.02
Created: ProtoTRAK LX2 [PE] L350.85.03
Comment: Corrected & cleaned up Threading Canned Cycle.
Jim Radcliffe}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '00'
#7 = 'ą##0.0000;0.'
#8 = '0.0#;0.'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FinishZ#,2)
FORMAT(InFeedAngle#,2)
FORMAT(FinishXDia#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(Recall#,6)
FORMAT(ThreadStarts#,6)
FORMAT(ADD#,7)
FORMAT(CycleStartZ#,7)
FORMAT(MUL#,8) { GetFeedRateC formula }
{Special Command Subroutines ***********************************************}
BeginMajorDia#: { Major Diameter at the beginning of threading }
IF ApproachOD?
ADD# FinishXDia# MUL# Num#('2') ThreadXInc#
ELSE
ADD# NUM#('0') FinishXDia#
END
RETURN
EndMajorDia#: { Major Diameter at the end of threading }
IF ApproachOD?
ADD# FinishXDia# MUL# Num#('2') ADD# ThreadXInc# Taper#
ELSE
ADD# FinishXDia# MUL# Num#('2') Taper#
END
RETURN
ThreadingPasses#:
{ count and output the number of threading passes}
Save# Num#('1') Num#('0')
EachFeat
IF ThreadFeat?
Save# Num#('1') ADD# Recall# Num#('1') Num#('1')
END
NextFeat
Recall# Num#('1')
RETURN
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
GetFeedRateC:
IF Flag?('1')
SetFlagF('1')
' F' MUL# SpeedRPM# FeedIPR#
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
GetFeedRateC
END
RETURN
ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN
AppMove:
StockOff ThisOpEntryZCP
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid
IF ApproachOD?
SeqC StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN
CheckOffset:
DoEndOpPS
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC GetFeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc GetFeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC FeedC MoveXC MoveZC GetFeedRateC EOL
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxFeed('500')
SetFlagF('1') { No FeedRate Output necessary }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
SetFlag('1') { Conditional FeedRateC Converted to IPM }
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq OpToolID ' G20' EOL { Inch }
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
{Start new Operation}
DoOpComments
DoPostScript
Seq OpToolID EOL
Approach
ELSE
IF SameTool? {.62}
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SetFlag('1') { Conditional FeedRateC Converted to IPM }
ELSE
IF NotEqual? FeedIPR# LAST FeedIPR#
SetFlag('1') { Conditional FeedRateC Converted to IPM }
ELSE
SetFlagF('1') { No FeedRate Output necessary }
END
END
{Start new Operation}
StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Threading?
SeqC LCycle
SetTTOff
' XB' BeginMajorDia# 'A'
' ZB' CycleStartZ# 'A'
' XE' EndMajorDia# 'A'
FinZ 'A'
ThrdLead
' NP' ThreadingPasses#
' A' InFeedAngle#
IF ApproachOD?
' SI1'
ELSE
' SI0'
END
' ST' ThreadStarts#
OpToolID EOL
SetTTOk
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
ELSE
IF Drilling?
IF Peck?
SetFlag('1') { Conditional FeedRateC Converted to IPM }
SeqC LCycle ' ZB' CycleStartZ# 'A' ZDepth 'A' GetFeedRateC
Save# Num#('1') Num#('0')
EachFeat
IF LineFeat?
Save# Num#('1') ADD# Recall# Num#('1') Num#('1')
END
NextFeat
' NP' Recall# Num#('1') EOL
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqC ZOpECPC EOL
FaceApproachSP
ELSE
SeqC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Threading?
SetPass1
FORMAT(MUL#,2)
SeqC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
FORMAT(MUL#,8)
SeqC FeedC
IF Taper?
' X' FinishXDia#
END
' Z' FinishZ# GetFeedRateC EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
ProtoTRAK LX2 L317 85Cin Acr CNC L367 85 03Fanuc 18T [ r] L394 85 03Prototrak Plus [PE] M808 89Prototrak MX2 [PE] M803 8703 10 09 (85)Yasnac LX2 HS TPS L099 85863 03ALL L130310?lass101Mode 03 Chaos Modewięcej podobnych podstron