{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}
{Change Comments ***********************************************************}
{6/14/95, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{ Format: Fanuc 18T [-R] Lxxx.85.02
11/21/95
For: Tamshell
Arcs now output R's instead of IJK
Changed prog label ID from O to :
TH}
{9/14/96
Initial: Fanuc 18T [-¨] L394.85.02
Created: Fanuc 18T [+¨] Lxxx.85
ForUser: Resistoflex
Control: ????
Machine: ????
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readout from Ed Braga.
Changed to PosSideLathe and StandardXZArcs.
Moved tool comments to beginning DoOpComments and dropped unconditional sequence
before its call.
Added 'M98P1' to beginning of tools.
Replaced Home commands at end of tools with 'M98P1'.
Jim Radcliffe}
{4/29/98
Initial: Fanuc 18T [+¨CR] L518.85
Created: Fanuc 18T Hard [GS] L723.85
ForUser: Green Specialty
Control: Fanuc 18T & Fanuc 21T
Machine: Hardinge T42 & Hardinge Cobra 65
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: New processor per marked up readout from Richard Green
Deleted Preset Home.
Geoemtry offset stored and activated with tool offset!
Preset is used of MaxRPM only in CSS operations.
Added 'M98P1' to beginning NewTool.
Put back DoOpComments to standard set up.
Changed OpToolID '00' to OpToolID LatheOffset at beginning of tools.
Deleted OpToolID LatheOffset from Approach.
Modified Canned Cycles per fax of pages from manual.
Updated per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}
{7/22/98,
Initial : Fanuc 18T Hard [GS] L723.85
Created: Fanuc 21T Hard [JT] L751.85
Customer: Jiffy-tite Comp, Jim Messecar - 716/681-7200
Changes to "Form":
1. Under Default Format, added ###.####;0. to W.
2. Under Lathe Drill Cycles, changed both Peck cycles to be: Label - P, Code - 9136,
Format - ###.####;0., Zdep - K, Rlev - Z, Dwl - A, Peck - W, and Ret - B
3. Under Turn Rough-OD/ID, changed Depth of Cut (U) Format to ####.####;0.
4. Under Turn Rough-Face, changed Depth of Cut (W) Format to ####.####;0.
Changes to "Prog":
1. Combined Program# and comment to one block. Changed ':' to 'O'.
2. Added two parameter blocks and a macro call block at tape start.
Also added FORMAT for HomeX# & HomeZ#.
3. Added G99 code (IPR mode) to the Approach sub.
4. Changed Peck Drilling cycles per customer spec.
5. Changed RoughContour cycles (G71 & G72) per customer spec.
6. Changed RoughPatternShift cycle (G73) per customer spec.
7. Changed Threading cycle (G76) per customer spec.
8. Changed #8 and #9 FORMAT and added #10 Format.
JHE}
{2Nov98
Original: Fanuc 21T Hard [JT] L751.85
Created: Fanuc 21T Hard [JT] L751.85.1
For: Jiffy-tite Co, Inc.
Changes made per: Jim Messecar
Added Post Header Comment at the top of Prog.
Changed '#501=12' to '#503=12' and '#502=12' to '#504=12' In FirstOperation
Changed 'M98P1' to 'M98P3' in FirstOperation and NewTool, Finish off last Operation
Added SpinCoolOn Sub and changes CoolOn to SpinCool in AppMove and CheckOffset.
Charles Winston}
{11/3/98,
Initial: Fanuc 21T Hard [JT] L751.85.1
Created: Fanuc 21T Hard [JT] L751.85.2
For: Jiffy-Tite Co.
Changes to Form:
1) Spindle and Coolant - Switched M3 and M4 codes.
Changes to Prog:
1) Changed all 'M98P1' calls to 'M98P3'.
2) Deleted calls to SpinOn except for in SpinCoolOn sub. Customer wants
to use M13 and M14 calls. SpinCoolOn will output this on same line as
Tool Calls.
CDH}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
{#8 = '00'} {Changed - JHE}
{#9 = '###^###0'} {Changed to #10 - JHE}
#8 = '0^0;00' {Added for thread chamfer - JHE}
#9 = '00;00' {Added for thread angle & # of spring passes - JHE}
#10 = '^###0' {Added for minmun depth of cut - JHE}
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPZ#,2)
FORMAT(HomeX#,2) {Added - JHE}
FORMAT(HomeZ#,2) {Added - JHE}
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(SpringPasses#,9)
FORMAT(CutDepth#,10) {Changed from 9 - JHE}
FORMAT(LastCutXRadius#,10) {Changed from 9 - JHE}
{Special Command Subroutines ***********************************************}
SpinCoolOn:
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
'M14'
ELSE
'M13'
END
END
RETURN
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# '; ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# '; ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN
ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN
AppMove:
StockOff ThisOpEntryZCP
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid 'G99' RapidF# { RapidF# Forces FeedRate } {Added G99 (IPR mode) - JHE}
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
END
END
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
LOfstOff '00'
END
EOL
SeqLabC
IF NewToolOffset?
OpToolID LatheOffset
END
IF LAST ProgStop?
SpinCoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SpinCoolOn
END
END
EOL
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript;' EOL
' Literals; put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands; must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'O' Program# {Changed from ':' - JHE}
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL {Moved to here - JHE}
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT; ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
'#503=' HomeX# EOL
'#504=' HomeZ# EOL
SeqLabC 'G65P9150H2.5' EOL {collet close time macro - JHE}
SeqLab ' M98P3' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
OpToolID LatheOffset SpinCoolOn EOL
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC 'M98P3' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation}
DoOpComments
DoPostScript
SeqLab ' M98P3' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
OpToolID LatheOffset SpinCoolOn EOL
Approach
ELSE
IF SameTool? {.62}
{Start new Operation}
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R' MUL# CutDepth# Num#('0.5') EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace? {Added this check - JHE}
{SeqLab StepMove StrtPos EOL} {Removed - JHE}
SeqLab StepMove ZSP EOL {Added - JHE}
SeqLabC FeedC 'G99' XSP FeedRate EOL {Added - JHE}
ELSE {implies OD or ID}
SeqLab StepMove XSP EOL {Added - JHE}
SeqLabC FeedC 'G99' ZSP FeedRate EOL {Added - JHE}
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
{SeqLab Rapid StrtPos EOL} {Removed - JHE}
SeqLab Rapid XSP EOL {Added - JHE}
SeqLabC Feed 'G99' ZSP FeedRate EOL {Added - JHE}
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
{1st block}
SeqLabC LCycle 'P' SpringPasses#
FORMAT(MUL#,8)
MUL# RunOutZ# Thread# {Run out is output in units of lead}
FORMAT(MUL#,9)
MUL# InFeedAngle# Num#('2')
FORMAT(MUL#,2)
FORMAT(LastCutXRadius#,10)
'Q' LastCutXRadius# {min depth of cut = last cut}
FORMAT(LastCutXRadius#,2)
'R' LastCutXRadius# EOL
{2nd block}
SeqLabC LCycle XatFinZ FinZ XTapAtZ
IF Taper?
{XTapAtZ}
END
ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck? {Changed to macro call - JHE}
SeqLabC 'G65' LCycle ZDepth Retract FeedRate Peck
'C' MUL# ToolDiameter# Num#('0.5')
IF Dwell?
Dwell EOL
ELSE
'A0.' EOL
END
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinCoolOn EOL
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC 'M98P3' EOL
SeqLabC UnTool '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH; ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH; ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH; ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 21T Hard [SA] L762 85Fanuc 21T MS [WIKA] L837 85Fanuc 0T Hard ST25 L510 85 1Fanuc 21T MS [CST] L799 85 1Fanuc 21T MS [VE] L718 85Fanuc 21T MS [ EMT] L642 85Fanuc 21T Tksw [DM] L823 85 1Fanuc 21T MS [WCS] L558 85 1Fanuc 18T Hard [SMT] L545 85 1Fanuc 21T Okuma Howa L555 85 1Fanuc 0TB Hard [AM] L391 85 1Fanuc 21T MS0 M42 [ ] L476 85Fanuc 18T Hard [DMAFB] L542 85Fanuc 18T Hard [GS] L723 85Fanuc 21T [MPG] L733 85 2Fanuc 21T B&B L791 85więcej podobnych podstron