{Change Comments ***********************************************************}
{3/9/89 minor corections by JR}
{4/25/89
Copied & Modified; Fanuc 10T-MS [-] L001.58, for Brunswick.
Machine is a Cincinnati Series 208 Turning Center, Acramatic 850TC
Jim Radcliffe}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/17/91, Updated Cincinnati Acr 850TC L102.56 to .81 format, JR}
{08/06/91
Updated: Cincinnati Acr 850TC L102.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}
{08/06/91
Using "Reference Rewind Stop" characters (:) unstead of SeqLab (N) at beginning of operations.
Changed the startup code per the manual, ':' Program# Rapid Plane 'G62G70' AbsOrInc 'G95' Home GearRange EOL.
Added the GetSpinOn sub to differentiate the 'M13' from 'M03' and 'M14' from 'M04'.
The GetSpinOn replaced the SpinOn command throughout the processor.
Added the missing NextOp at the end of the prog.
Put the EOP on the same line as the FirstHome, per the manual.
Deleted the ProgStop and the Untool ToolChng from the end of the prog.
Kim Michelman}
{6/8/93
Copied & modified: Cincinnati Acr 850TC L102.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Use sequence number for colon blocks.
Added leading zero supression on G & M & T codes.
Changed ToolChng from M26 to M6.
Modified GearRanges.
Added XsAreRadii to initializations.
Added CoolOff at end of tool.
Reduce RPM to 125 at end of tool if next tool has a new gear or spindle direction.
Changed to use absolute arc centers.
Added spaces between codes.
Deleted "XatFinZ ThrdHeight" line before thread cycle.
This was to position to the major dia,
set CAM document to have Start X and Major Ż set the same.
Jim Radcliffe}
{8/6/93
Modified: Cin Acr 850 TC [IM] L289.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Modified retract to index position.
Machine has 2 turrets: Lower = Tools 1 thru 6 Upper = Tools 11 thru 16
When indexing from Lower to Upper retract Z to NewHome + 20"
When indexing from Upper to Lower retract X to NewHome + 13"
Unconditional axis output in FormatArc.
Deleted extra Rapid from Approach.
Moved callout of CSSOn for FirstOp and NewTool.
Changed format of output from 0. to 0 for a zero output.
Due to a recent visit to the Twilite Zone,
I had to start with a fresh Form (I used L001) to get this to work.
Colon block must imediatly follow a program stop.
Moved ProgStop to a line by itself after DoOpComments in same tool.
Rewrote CheckOffset to add Colon Block if ProgStop.
Modified R value for Threading by .050 for clearance
Jim Radcliffe}
{11/1/94
Copied & modified: Cin Acr 850 TC [IM] L289.82.2
For: Accurate Tool Co.
Control: Acramatic 850 SX
Machine: Cincinnati Milicron Avenger
Changed G76 to G33 for Threading Canned Cycle.
Moved EOP down to line by itself.
Added 1 NULL character to end of program.
Added X and I values for Tapered threading.
Jim Radcliffe}
{4/11/95
Initial: Cin Acr 850 SX L315.82.2
ForUser: CNCCS / Superior Jig
Control: Acramatic 850SX
Machine: Cincinnati Milicron Talon - Single Turret
Develop: ComPost 4.21.26, Catalyst v2.14.38C
New Post Processor per marked up readout. Highlights:
Deleted XsAreRadii to output diameter values.
Modified colon blocks.
Rewrote CSS handling.
Deleted GearRange.
Deleted the Program# comment.
Removed dual turret handling.
Added PeckFllRetract cycle to MachSpec.
Separate SpinOn and CoolOn commands.
Changed to R Format arcs. Address is a P !?!?
Changed ThrdLead to Thread# to output the threads per inch value
Jim Radcliffe}
{5/1/95, .82.3, added SpinOff, deleted DrillOff, changed thread R and X values to diameter. JR}
{11/26/97
Initial: Cin Acr 850 SX [SJ] L345.82.3
Created: Cin Acr 850 SX [SJ] L345.85
Develop: ComPost2 1.1b3, Virtual 4.21.14
Comment: Updated to .85 format
Jim Radcliffe}
{Prog Numeric Format Definitions *******************************************}
#1 = '0.00'
#2 = '##.#0'
#3 = '###.0###;0'
#4 = '+#.0###;0'
#5 = '#####0'
#6 = '0000'
#7 = '#'
#8 = '##.0;0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(StartPosX#,3)
FORMAT(CycleStartXRadius#,3)
FORMAT(ADD#,3)
FORMAT(MUL#,3)
FORMAT(NewHomeX#,3)
FORMAT(NewHomeZ#,3)
FORMAT(FirstHomeX#,3)
FORMAT(FirstHomeZ#,3)
FORMAT(HomeX#,3)
FORMAT(XCutDepth#,4)
FORMAT(ZCutDepth#,4)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Thread#,5)
FORMAT(Program#,6)
FORMAT(RapidF#,7)
FORMAT(InFeedAngle#,8)
{Prog Subroutines **********************************************************}
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN
ODApproachSP:
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC StockOnNoCan ZSPC EOL
END
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
IDApproachSP:
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC StockOnNoCan ZSPC EOL
END
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN
AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
{tool offsets not used in this processor}
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
SeqLabC SpeedC
ELSE
SeqLabC Preset MaxRPM
{set G96 in main after StrtPos}
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
ELSE
SeqLabC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqLabC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('1600')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EACHOp
Plane
TagInc
GetLCycle
IF FirstOperation?
SetHome
IF UseComments?
IF ProgramNameComment?
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
':?' Rapid ' G62' ' H1' Home EOL
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff OpToolID ToolChng CalcRPM1 SpinOn EOL
SeqLabC Rapid Home EOL
SeqLabC CSSOn ' G95 G96 R' HomeX# Speed ' F.020' EOL
ELSE
SeqLabC Preset ' S1200' EOL
SeqLabC CSSOff OpToolID ToolChng Speed SpinOn EOL
SeqLabC ' G95 G97' Speed ' F.020' EOL
END
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
SeqLabC LAST OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
SeqLabC NewHome SpinOff EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation}
':?' Rapid ' G62' ' H1' Home EOL
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff OpToolID ToolChng CalcRPM1 SpinOn EOL
SeqLabC Rapid Home EOL
SeqLabC CSSOn ' G95 G96 R' HomeX# Speed ' F.020' EOL
ELSE
SeqLabC Preset ' S1200' EOL
SeqLabC CSSOff OpToolID ToolChng Speed SpinOn EOL
SeqLabC ' G95 G97' Speed ' F.020' EOL
END
Approach
ELSE
IF SameTool? {.62}
DoEndOpPS
{Start new Operation}
DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST NOT ConstantSurfaceFeed?
SeqLabC CSSOn ' G96 R' StartPosX# Speed EOL
END
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
SeqLabC Feed Feedrate EOL
SeqLabC '(BAR,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
CutDepth XStkLeft ZStkLeft XSP ZSP ')' EOL
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC Feed Feedrate EOL
SeqLabC '(CPY,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
XStkLeft ZStkLeft XSP ZSP ')' EOL
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
END
END
ELSE
IF Threading?
SeqLabC '(THD,' CutDepth
IF SingleEdgeCut?
' A' InFeedAngle#
ELSE
' A0'
END
' R' ADD# CycleStartXDia#
IF ApproachOD?
Num#('.1')
ELSE {Approach ID}
Num#('-.1')
END
XatFinZ ZSP ')' EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
IF Taper?
XAtFinZ FinZ ' I' MUL# DIV# Num#('1') Thread# DIV# Taper# FinishZInc#
ELSE
FinZ
END
' K' Thread# EOL
SeqLabC '(ENC)' EOL
IF AutoFinish?
SeqLabC Rapid XatFinZ ZSP EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
FinZ ThrdLead EOL
SeqLabC RapidC ' X' CycleStartXRadius# EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? AND NOT Drilling?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
SeqLabC OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
SeqLabC NewHome SpinOff EOL
SeqLabC EOP EOL
IF UseComments?
SetScale('1')
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Post
ASCII('00') EOL
Close
Retag
Wyszukiwarka
Podobne podstrony:
Cin Acr 850 SX [WF] L592 85Cin Acr 850 SX [WT] L381 85 3Cin Acr 850 SX [STM] L437 85 10Cin Acr 850 SX R [MOP] L675 85Cin Acr 850 SX [WSR] L583 85 1Cin Acr 850 SX [AG] L590 85 8Cin Acr 850 SX [STM] L437 85 9mCin Acr 850 SX [SI] L324 85 5Cin Acr 850 SX [CS] L519 85 1Cin Acr 850 SX [BCA] L665 85Cin Acr 850 SX [SI] L324 85 4mCin Acr 850 SX [CG] L819 85Cin Acr 850 SX [BRC] L742 85Cin Acr 850 SX [AA] L808 85Cin Acr 850 SX [YI] L456 85Cin Acr 850 SX [GT] L738 85 1Cin Acr 850 SX L315 85więcej podobnych podstron