{Made from L022 TF per Caricof 1/5/89}
{3/29/90, Updated: Okuma OSP 2200 LSN10 L089.54 to .69.3 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/17/91, Updated Okuma OSP 2200 LSN10 L089.71 to .82 format, JR}
{10/29/96,
Initial: Okuma OSP 2200 LSN10 L089.82
Created: Okuma OSP 2200 Lxxx.82
For: Craftco
Added GetSpinOn and GetInverseSpinOn subs to replace SpinOn and
InverseSpinOn. GetSpinOn putputs M3 for Tools under 5 and M4 for tool over #5, GetInverseSpinOn
does the opposite.
Moved the GearRange call from the beginning of the common point to Approach
sub and also in CheckOffset (output is conditional upon the Speed changing),
Deleted Material and tool list stuff form FirstOp,
Deleted literal S12 form tool call lines in FirstOp and NewTool,
Added CoolOff to NewHome line in NewTool,
Deleted all EOR commands,
Deleted literal 'JAWS-' from end section,
Changed EOP in form to M2,
MPK}
{6 Oct97
Original: Okuma OSP 2200 L532.82
Created: Okuma OSP 2200 [CMS] Lxxx.82
For: Craftco Metals Services
Changes made per: Randy
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Formatted N to ##000^b in MachSpec
Added formatting for DIV# in Prog Numeric Format Definitions
Moved OpToolID ToolOffset# GetSpinOn and CoolOn from AppMove to FirstOp and NewTool
Moved GearRange from Approach to FirstOp and NewTool
Added Rapid Home to the initial move in FirstOp and NewTool
Deleted ConstantVolumeCut thread Cycle and replaced it with a 'G33' SimpleRough cycle
Added Rapid Home at the end of the Threading Cycle
Deleted ThrdLead and replaced with the 'F' inverse of Thread#
Charles Winston}
{ 6th Oct 97, Updated to .85 for Catalyst v2.20 per FANUC 10T [-] L001.85, Charles WInston }
{11/6/97,
Initial: Okuma OSP 2200 [CMS] L532.85
Created: Okuma OSP 2200 [CMS] L532.85.1
For: Craftco Metals Services
Deleted Rapid and Home in IF Threading.
Added FeedC and FeedRateC in IF RoughContour and IF RoughPatternShift.
Deleted StepMove in IF RoughContour.
CDH}
{Prog Numeric Format Definitions *******************************************}
#1 = '0.00'
#2 = '###^#0'
#3 = '###^####;0'
#4 = '0'
#5 = '########;0'
#6 = '#'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(FirstMoveEPX#,3)
FORMAT(DiaDistanceToThread#,3)
FORMAT(DIV#,3)
FORMAT(ToolOffset#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(RapidF#,6)
{Prog Subroutines **********************************************************}
GetSpinOn:
IF ToolOver?('4')
'M4'
ELSE
'M3'
END
RETURN
GetInverseSpinOn: {used in place of InverseSpinOn in tapping}
IF ToolOver?('4')
'M3'
ELSE
'M4'
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN
CheckFeed:
IF NOT Threading?
Feed
END
RETURN
CheckFeedRate:
IF NOT Threading?
FeedRate
END
RETURN
ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC CheckFeed ZSPC CheckFeedRate EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC CheckFeed XSPC CheckFeedRate EOL
END
END
RETURN
AppMove:
StockOff ThisOpEntryZCP
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '0' EOL
SeqC OpToolID ToolOffset# EOL
END
IF LAST ProgStop?
SeqC GetSpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT Equal? SpeedRPM# LAST SpeedRPM#
SeqC GearRange EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4F2000' EOL
SeqC Speed GetInverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G4F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
OpenSub
StockOff {.71.2}
SetHome
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
DoOpComments
DoPostScript
Plane
Seq
IF ToolOver?('4')
'G14'
ELSE
'G13'
END
GearRange Rapid Home OpToolID ToolOffset# GetSpinOn CoolOn EOL
Approach EOL
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC XCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
SeqC NewHome CoolOff EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
{Start new Operation}
DoOpComments
DoPostScript
SeqC
IF ToolOver?('4')
'G14'
ELSE
'G13'
END
GearRange Rapid Home OpToolID ToolOffset# GetSpinOn CoolOn EOL
Approach EOL
ELSE
IF SameTool? {.62}
{Start new Operation}
StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
SeqC FeedC FeedRateC EOL
SeqC 'G85' EOL
IF ApproachFace?
SeqC 'G82' EOL
END
SeqC CutDepth
IF ApproachFace?
ZStkLeft
ELSE
XStkLeft
END
EOL
SeqC StrtPos EOL
ToolPath
SeqC 'G80' EOL
ELSE
IF RoughPatternShift?
SetPass2
SeqC FeedC FeedRateC EOL
SeqC 'G86' EOL
IF ApproachFace?
SeqC 'G82' EOL
END
SeqC Rapid
IF ApproachFace?
ZminusW
ZStkLeft
ELSE
XminusU
XStkLeft
END
EOL
SeqC StrtPos EOL
ToolPath
SeqC 'G80' EOL
END
END
ELSE
IF Threading?
IF Chamfer?
SeqC 'M23' EOL
END
SeqC 'G33X' FirstMoveEPX# FinZ 'F' DIV# NUM#('1') Thread# EOL
SimpleRough
SeqC 'G80' EOL
IF AutoFinish?
SeqC XatFinZ EOL
END
IF Chamfer?
SeqC 'M22' EOL
END
ELSE
IF Drilling?
SeqC 'G83' EOL
SeqC 'G82' EOL
SeqC Peck 'E0' EOL
SeqC Feed ZDepth FeedRateC EOL
SeqC 'G80' EOL
IF AutoFinish?
SeqC Feed ZDepth EOL
SeqC Rapid RLevel EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G4P2000' EOL
SeqC Speed GetSpinOn EOL
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC CoolOff EOL
SeqC FirstHome
IF ProgStop?
'M0' EOL
ELSE
ProgStop EOL
END
SeqC EOP EOL
Post
Close
IF UseComments?
Reopen
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Okuma OSP 5020L [PB] L604 85 1Okuma OSP 2200 LSN10 L089 82Okuma OSP 5000 [NC] L606 85 1Okuma OSP 5020 [TPM] L572 85Okuma OSP 5020L [CP] L787 85Okuma OSP 7000L [JDHW] L707 85 1mOkuma OSP 3000 LC20 L049 85Okuma OSP 5020L [WMC] L676 85 3Okuma OSP 5500 Cadet L331 85Okuma OSP 5020L [GCS] L540 85Okuma OSP 5020L [MP] L626 85Okuma OSP 5020 [MM] L806 85Okuma OSP 5020 [IP] L523 85 1więcej podobnych podstron