{Change Comments ***********************************************************}
{7/7/95, Updated for Catalyst v2.20 per Fanuc 6M M001.10 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{1/17/96, Updated .85 to .86 version, MPK}
{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}
{7/12/96
Modified: Fanuc 6M M001.12
Created: Fanuc 6M M001.13.1
For: Gibbs & Associates
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Updated to .13 version.
DWB}
{10/2/96, updated to .14 format per Fanuc 6M (FW) B001.14, MPK}
{11/22/96
Versions: Catalyst v3.23C/Compost 4.21.37/v1.0b1
.14 Additions:
Deleted Flag(2) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}
{2/25/97
Modified: Fanuc 6M M001.14
Created: Fanuc 6M M001.15
For: Gibbs & Associates
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
DWB}
{7Jul97
Original: Fanuc 6M M001.15
Created: Brother 324 [LE] Mxxx.15
For: Lunde Engineering
Changes made per: Jim Lunde
Control: Brother 323
Changed Dwell# from FORMAT#6 to FORMAT#2
Added literal 'S O' and changed ProgID1 formatting at the start of InitOp to customers requirements.
Added FORMAT#7 and assigned Program# in InitOp. Customer requires leading zeros here.
Added ASCII(26) at End3
Charles Winston}
{02/20/98,
Initial: Brother 324 [LE] MX52.15
Created: Brother 324 [LE] NMV15.15.1
For: Lunde Engineering
Changed to a LongHand post, based on Dan Ball's LongHand M001.15
CDH}
{01/29/99,
Initial: Brother 324 LH [LE] MV15.15
Created: Brother 324 LH [LE] MV15.15.1
For: Lunde Engineering
Changes to Prog:
1) The post didn't have a return after the last End3 call. This often causes the post not to
execute the last command. A return was entered and the post works fine.
CDH}
{Prog Numeric Format Definitions ****}
#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'
#8 = '#'
#9 = 'ą#bbbb.bbbb#'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(Recall#,5)
FORMAT(PartNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(RapidF#,8)
FORMAT(PartShiftX#,9)
FORMAT(PartShiftY#,9)
FORMAT(PartShiftZ#,9)
{Testing Subroutines *}
#20 = 'ą0000.0000'
FORMAT(OriginShiftPX#,20)
FORMAT(OriginShiftPY#,20)
FORMAT(OriginShiftPZ#,20)
FORMAT(OriginUnshiftPX#,20)
FORMAT(OriginUnshiftPY#,20)
FORMAT(OriginUnshiftPZ#,20)
FORMAT(OriginUSPXCTP#,20)
FORMAT(OriginUSPYCTP#,20)
FORMAT(OriginUSPZCTP#,20)
Report:
IF MultipleParts? AND WorkFixtureOffsets?
SetStatusOff
' ' EOL
' PartShiftX# = ' PartShiftX# ' '
' PartShiftY# = ' PartShiftY# ' '
' PartShiftZ# = ' PartShiftZ# EOL
'OriginUnshiftPX#(0) = ' OriginUnshiftPX#('0') ' '
'OriginUnshiftPY#(0) = ' OriginUnshiftPY#('0') ' '
'OriginUnshiftPZ#(0) = ' OriginUnshiftPZ#('0') EOL
'OriginUnshiftPX#(1) = ' OriginUnshiftPX#('1') ' '
'OriginUnshiftPY#(1) = ' OriginUnshiftPY#('1') ' '
'OriginUnshiftPZ#(1) = ' OriginUnshiftPZ#('1') EOL
'OriginUnshiftPX#(2) = ' OriginUnshiftPX#('2') ' '
'OriginUnshiftPY#(2) = ' OriginUnshiftPY#('2') ' '
'OriginUnshiftPZ#(2) = ' OriginUnshiftPZ#('2') EOL
' OriginShiftPX# = ' OriginShiftPX# ' '
' OriginShiftPY# = ' OriginShiftPY# ' '
' OriginShiftPZ# = ' OriginShiftPZ# EOL
' OriginUSPXCTP#(0) = ' OriginUSPXCTP#('0') ' '
' OriginUSPYCTP#(0) = ' OriginUSPYCTP#('0') ' '
' OriginUSPZCTP#(0) = ' OriginUSPZCTP#('0') EOL
' OriginUSPXCTP#(1) = ' OriginUSPXCTP#('1') ' '
' OriginUSPYCTP#(1) = ' OriginUSPYCTP#('1') ' '
' OriginUSPZCTP#(1) = ' OriginUSPZCTP#('1') EOL
' OriginUSPXCTP#(2) = ' OriginUSPXCTP#('2') ' '
' OriginUSPYCTP#(2) = ' OriginUSPYCTP#('2') ' '
' OriginUSPZCTP#(2) = ' OriginUSPZCTP#('2') EOL
' ' EOL
SetStatusOn
END
RETURN
{Prog Subroutines ****}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
WFONum:
'G' NewWFO#
RETURN
WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
SetWFO
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN
ResetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN
DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' PartNum# ' )' EOL
END
RETURN
DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN
PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC FeedC ZInC
IF NOT EmptyLine? { Mostly for FeedConnect ZShiftOnly with ZMove }
FeedEntC
END
EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN
ExitMove:
IF NOT FeedConnect?
CRCOffC
IF FIFO?
FeedC PRIME ZCP2C FeedEntC
ELSE
RapidC PRIME ZCP2C
END
END
RETURN
ExitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN
CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN
ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN
DoPeck:
IF GreaterThan? SUB# Recall# Num#('3') Peck# SPZ# { IF OldZ - Peck# > Depth }
Save# Num#('3') SUB# Recall# Num#('3') Peck# { Save#8 NewZ }
SeqC Feed 'Z' Recall# Num#('3') FeedEntC EOL { Move to NewZ }
Rapid
IF PeckFullRetract?
SeqC ZCP2 EOL { Retract Tool Full Out }
END
SeqC 'Z' ADD# Recall# Num#('3') Retract# EOL { Move to Retract Pos }
TrackZNO# ADD# Recall# Num#('3') Retract# { Update Status Register }
END
RETURN
DrillFeature:
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
IF Peck?
FORMAT(Recall#,4)
Save# Num#('3') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
FORMAT(Recall#,5)
END
SeqC FeedC MoveSZC FeedEntC EOL
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
IF FIFO? OR Tap?
SeqC FeedC ZCP2C EOL
IF RetractToCP1?
SeqC RapidC ZCP1C EOL
END
ELSE
IF RetractToCP1?
SeqC RapidC ZCP1C EOL
ELSE
SeqC RapidC ZCP2C EOL
END
END
RETURN
ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN
AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
EntryMove
ToolPath
RETURN
G92Sub:
RETURN
XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC EOL
END
IF ZShiftOnly?
EntryMove
ELSE
IF NOT NoZMoves?
EntryMove
END
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
SeqC ExitMove EOL
NextRep
RETURN
NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN
XYZRepAutoCycle:
CycleWarning
EachRep
DoCycleComment
IF NOT FirstCycle?
IF FIFO?
Rapid
END
SeqC RapidC StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
EACHFeat
IF NOT FirstFeat?
DoCycleComment
END
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
SeqC CRCOffC
LoadFeat Num#('0') Num#('0') PRIME ClearancePlane2#
IF ZMove?
ExitMove
END
EOL
NextRep
RETURN
ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqC AbsOrInc ExitMove EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC RapidC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN
ZonlyRep:
RETURN
LongDrillStuff:
SeqC DrillCP EOL
GetCycle
SeqC StrtPosC EOL
RETURN
DrillStuff:
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
SkipToLastFeat:
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
OpGuts:
ResetCRCNum
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
{ For LongDrillStuff
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC RapidC ZCP3C EOL
END}
{ For DrillStuff }
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
END
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { LongHand PeckCycle }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN
InitOp:
FORMAT(Program#,7)
EOR 'S O' Program# ' ' EOL {Lunde's control needs 3 spaces after the program name}
FORMAT(Program#,5)
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
RestoreScale
RETURN
FirstOp1:
Seq Plane 'G80' CRCOff EOL
SeqC OpToolID EOL
SeqC ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
RETURN
FirstOp2:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN
FirstOp3:
SeqC OfstOn EOL
SeqC CoolOn EOL
RETURN
NewToolOp1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
RETURN
NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN
NewToolOp3: {Start new Operation}
Seq Plane 'G80' CRCOffC EOL
SeqC OpToolID EOL
SeqC ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
RETURN
NewToolOp4:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN
NewToolOp5:
SeqC OfstOn EOL
SeqC CoolOn EOL
RETURN
SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
END
RETURN
SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
SeqC WFOStuff EOL
RETURN
SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN
End1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
RETURN
End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN
End3:
SeqC EOP EOL
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
SetFlag('2') { WFOStuff }
IF FirstOperation?
IF FirstPart?
FirstOp1
FirstOp2
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
SetFlag('2') { WFOStuff }
IF FirstOperation?
IF FirstPart?
FirstOp1
FirstOp2
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN
NoMPs: {no multiple parts}
SetFlag('2') { WFOStuff }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN
MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN
EndPartSub:
{End of program ************************************************************}
{finish last operation}
End1
IF MultipleParts? AND OneToolAllParts?
ResetWFO
END
End2
RETURN
DoNewPart:
{Finish off last Part}
IF FullUp?
SeqC Rapid ZCP1 EOL
END
{DoEndOpPS}
{Start new Part}
SetFlag('2') { WFOStuff }
SameToolOp2
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
RETURN
MPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
NewWFO
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
MasterSub
NextOp
EndPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Tool First Op }
IF FirstOperation? OR NewTool?
IF NOT FirstPart?
DoNewPart
END
END
MasterSub
IF LastOp?
IF LastPart?
Save# Num#('1') Num#('0')
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart?
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IncWFO
NextWFO
ELSE
NextPart
END
RETURN
{Start of executable Prog, Top Level ****}
ProgStart {setup and initializations}
InitOp
IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
MPLoop
ResetWFO
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3
Wyszukiwarka
Podobne podstrony:
Brother 324 [LE] MX52 15Brother 324 [CT] DQ08 15Brother TC 228 CX17 15 2Le Monde Eudcation 2010 09 15 EDU324 32515 315Janequin C Le chant de l Alouette SATBProgram wykładu Fizyka II 14 1515 zabtechnŁódzkiego zwięcej podobnych podstron