{Change Comments ***********************************************************}
{5/20/93
Copied & modified: Fanuc 10M M008.81.2
For: Haas Automation
Combined OpToolID and ToolChng on one block at FirstOperation and NewTool.
Combined DoWFONum Speed SpinOn AbsOrInc Rapid StrtPos and OfstOn on one block at FirstOperation,
NewTool and SameTool.
Added CkCRC sub to cancel CutterRadiusCompensation on LastFeature of ToolPath.
Added literal 'G74' for Left-Handed Tapping at Drilling.
Moved Canned Drill Cycle Block to Main Program when Repeats = TRUE at Drilling.
Main program will output the Canned Drill Cycle, and the SubPrograms will contain only the
positions from the second feature on.
DWB}
{8/2/93
Modified: Haas M573.81.2
For: Haas Automation
Changes made per visit with Harold Moon at Haas Automation.
Added ProgramName$ to SubID block at StartSub.
Added blank lines between subs.
Deleted RepLab OnePart at OpenMP.
Moved Rapid, Feed and Connect Commands to be output in front of AbsOrInc on same block.
Deleted colons from all Comments.
Deleted Spaces following '(, and preceeding )' from ProgramNameComment at FirstOperation.
Changed Seq to 'N' Tool# EOL at FirstOperation and NewTool, output on block by itself.
Changed Safe Start block from G17G80G40 to G0G90G54G40G80G17 at FirstOperation and NewTool.
Changed StrtPos block from DoWFONum Speed SpinOn AbsOrInc Rapid StrtPos OfstOn to
Rapid AbsOrInc DoWFONum StrtPos Speed SpinOn at FirstOperation and NewTool.
Added PlaneC to StrtPos block at NewTool.
Moved OfstOn to beginning of CoolOn block at FirstOperation and NewTool.
Changed DoWFONum PlaneC AbsOrInc Rapid to Rapid AbsOrInc DoWFONum PlaneC at SameTool StrtPos block.
Added IF RetractToCP1 boolean at SameTool.
This is to force output of ZCP1 or ZCP2 for Drilling.
Changed RapidC ZCP3C to Rapid ZCP3 at Drilling.
Moved 'G80' to Rapid ZCP3 at Drilling.
Added literal 'M19', Spindle Orient, at OfstOff block at end of Prog.
Added MasterOp/CallMasterOp PostScript Command support for Drilling.
Routines have been added to call previously created subroutines.
Added MasterOpF and CallMasterOpF at PSInit.
Added PostScript Comments regarding MasterOp and CallMasterOp Commands.
Added support of MasterOp and CallMasterOp Commands at Drilling.
Added FORMAT for Recall# to output called sub.
DWB}
{9/19/95
Copied: Haas M573.81.2 & modified to HAAS (SMAC) M---.--.-
Set max RPM to 12000 and max Feed to 3000. Added tool change and comment to 'N' Tool#.
Set WFO numbers to run from G110 to G139, allowing 30 fixture offsets instead of 6.
Removed duplicate prep. codes from set up blocks. Remove 'R' Format Arcs. Removed some Comments.
Removed all M5's and added M19 to all OfstOff comands.
Sent Y axis to machine zero and changed to first tool at end of program.
KC}
{10/24/96
Modified: Haas (SMAC) M857.10
Created: Haas [HA] MZ67.13
For: Haas Automation
Versions: Catalyst v3.09C/Compost 4.21.37/v1.0b1
Changes made per Paul Cross of Haas Automation.
Updated for Catalyst v3.05C per Fanuc 6M M001.13.1 Format
Changed First Work Fixture Offset from G110 to G54 in Compost2 Origins and Values Dialog.
Changed Last Work Fixture Offset from G130 to G59 in Compost2 Origins and Values Dialog.
Added FeedEntC for SameTool Operations at EntryMove sub.
Commented out ResetCRCNum at ToolPath sub.
Customer only wants it output when it changes.
Added condition to output 'G' NewWFO# for FirstOperation or when changed via PostScript at WFOStuff
sub.
Moved SafeStart block from FirstOp2 sub to FirstOp1 sub.
Moved OpToolID ToolChng to separate block at FirstOp1 and NewToolOp3 subs.
Added AbsOrInc Rapid to StrtPos block at FirstOp3 sub.
Deleted SafeStart block at NewToolOp3 sub.
Changed Plane to PlaneC at NewToolOp3 sub.
Added AbsOrInc Rapid DoWFONum to StrtPos block at NewToolOp5 sub.
Added condition to output OperationIDComment for FirstOperation or NewTool only at DoOpComments.
DWB}
{4/10/97,
Initial: Haas [HA] MZ67.13
Created: Haas [HPD] Mxxx.13
Removed 'N' Tool# from FirstOp and NewTool, MPK}
{6/12/97,
Created: Haas [HPD] MY68.13.01 (from Haas [HPD] MY68.13)
For: High Precision Development
modifed CloseMP so that post would output movement to next part in a manner familiar to High Precision.
added additional format statements.
WS}
{6/23/97,
Created: Haas [HPD] MY68.13.02 (from Haas [HPD] MY68.13.01)
For: High Precision Development
changed coolant code position to be after the Tool Change block or before the OfstOn command.
changed end of program PreTool code to be the (Last Tool + 1).
WS}
{3Dec97
Original: Haas [HPD] MY68.13.2
Created: Haas [HPD] MY68.13.3
For: High Precision Devices
Changes made per: Bill Dougherty
Moved Speed SpinOn and CoolOn onto seperate Lines in FirstOp3 and NewToolOp5
Customer wants a limit of one M-code per line
Added Literal 'M31' in FirstOp3 { Swarf Conveyer Start }
Added SpinOff in End1
Added Literal 'X-15.' in End3
Charles Winston}
{15Dec97
Original: Haas [HPD] CY68.15
Created: Haas [HPD] CY68.15.1
For: High Precision Devices
Changes made per: Bill Dougherty
Moved SpinOff to the OfstOff line and Deleted Literal 'M19' in End1
Changed Literal G28 To G53 in End3
Added AbsValue 'M19' { Spindle Orient } in End3
Charles Winston}
{3Dec97, Created B_Style Advanced Mill Post Per Haas [QC] B587.15.1, Charles Winston }
{3Dec97, Created C_Style Advanced Mill Post Per Haas [QC] C587.15.1, Charles Winston }
{22Dec97
Original: Haas [HPD] CY68.15.1
Created: Haas [HPD] CY68.15.2
For: High Precision Devices
Changes made per: Bill Dougherty
Moved G53 line after AbsValue 'M19' in End3
Charles Winston}
{Prog Numeric Format Definitions ****}
#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(OriginShiftPX#,4)
FORMAT(OriginShiftPY#,4)
FORMAT(OriginShiftPZ#,4)
FORMAT(OriginUSPXCTP#,4)
FORMAT(OriginUSPYCTP#,4)
FORMAT(OriginUSPZCTP#,4)
FORMAT(Add#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
{Prog Subroutines ****}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN
CSWFO:
'G'
IF GreaterThan? ADD# CSPartNum# Num#('53') Num#('59')
ADD# ADD# CSPartNum# Num#('53') Num#('50')
ELSE
ADD# CSPartNum# Num#('53')
END
RETURN
WFO:
'G'
IF GreaterThan? ADD# PartNum# Num#('53') Num#('59')
ADD# ADD# PartNum# Num#('53') Num#('50')
ELSE
ADD# PartNum# Num#('53')
END
RETURN
WFOStuff:
IF Flag?('2')
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in subCSMP and closeMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2')
RETURN
CSG52:
IF FirstOperation? OR NewTool? OR ChangeCS?
SeqC WFOStuff 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
END
ClearCSOffset
RETURN
G52Stuff:
IF AAxisAvail? OR BAxisAvail?
IF NOT WFOCS?
IF MultipleParts?
IF WorkFixtureOffsets?
CSG52
END
ELSE
CSG52
END
END
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )' EOL
END
RETURN
DoCSComment:
IF AAxisAvail? OR BAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN
DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
IF FirstOperation? OR NewTool? OR ChangeCS?
'( ' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
END
ClearCSOffset
END
RETURN
CSComments:
IF WFOCS?
IF MultipleParts?
IF OneToolAllParts? AND ExitClearancePlane?
ClearCSOffset { Necessary for correct StrtPos in Main }
END
ELSE
DoCSComment
DoCSWFOComment
END
ELSE
DoCSComment
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF FirstOperation? OR NewTool?
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
RestoreScale
END
CSComments
RETURN
DoToolComment:
IF UseComments?
IF ToolComment?
'( ' ToolComment$ ' )' EOL { EOL needed here }
END
END
RETURN
DoProgramComment:
IF UseComments?
IF ProgramNameComment?
'(' ProgramName$ ')'
END
END
RETURN
CSAngleA:
IF AAxisAvail?
'A' CSOffsetA#
END
RETURN
CSAngleAC:
IF AChange?
CSAngleA
END
RETURN
CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN
CSAngleBC:
IF BChange?
CSAngleB
END
RETURN
PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN
EntryMove:
IF FeedEntry?
IF FirstOperation? OR NewTool?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC Feed ZIn FeedEntC EOL
END
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
' ' EOL
SubID DoProgramComment EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3 FeedEntC
ELSE
RapidC ZCP3
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN
ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN
DoCSG52Ops:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
IF GreaterThan? PartNum# Num#('6')
SeqC 'G' ADD# PartNum# Num#('103') EOL
ELSE
SeqC SetWFO EOL
END
END
SeqC SubCall CallLab EOL
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSG52Ops
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSG52Ops
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN
DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC CSWFO EOL
END
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
END
ELSE
SeqC 'G00X0Y0' EOL
TrackXNO# Num#('0')
TrackYNO# Num#('0')
SeqC Preset 'X' OriginShiftPX# 'Y' OriginShiftPY# EOL
SeqC EndSub EOL
CloseSub
SeqC Preset 'X' OriginUSPXCTP#('1') 'Y' OriginUSPYCTP#('1') EOL {ShiftRC EOL}
SeqC 'G00X0Y0' EOL
TrackXNO# Num#('0')
TrackYNO# Num#('0')
END
RETURN
SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
SetFlag('6')
END
END
RETURN
FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN
ckCRCNum:
IF Flag?('6')
SetFlagF('6')
CRCOffsetC
END
RETURN
ToolPath:
{ResetCRCNum}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc
ELSE
IF FIFO?
FeedC AbsOrInc ZCP2 FeedEntC
ELSE
RapidC AbsOrInc ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC Connect AbsOrInc StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF Repeats?
NewProg
StdSub
END
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('12000')
SetMaxFeed('3000')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('6') { True = need CRCOffset }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('26')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('26') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN
InitOp:
EOR EOL
ProgID1 DoProgramComment EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
END
OpenSub
RestoreScale
RETURN
FirstOp1:
SeqC Plane CRCOff 'G80' AbsOrInc Rapid WFOStuff EOL
SeqC OpToolID ToolChng DoToolComment DoOpComments EOL
DoPostScript
RETURN
FirstOp2:
RETURN
FirstOp3:
G52Stuff
CheckPass
SeqC Speed SpinOn EOL
SeqC CoolOn EOL
SeqC 'M31' EOL
SeqC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
RETURN
FirstOp4:
SeqC OfstOn EOL
RETURN
NewToolOp1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff 'M19' EOL { Spindle Orient }
SeqC AbsValue EOL
ELSE
SeqC OfstOff 'M19' EOL { Spindle Orient }
END
RETURN
NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN
NewToolOp3:
SeqC PlaneC EOL
SeqC OpToolID ToolChng DoToolComment DoOpComments EOL
DoPostScript
RETURN
NewToolOp4:
RETURN
NewToolOp5:
G52Stuff
CheckPass
SeqC Speed SpinOn EOL
SeqC CoolOn EOL
SeqC AbsOrInc Rapid WFOStuff StrtPos CSAngleA CSAngleB EOL
RETURN
NewToolOp6:
SeqC OfstOn EOL
RETURN
SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff 'M19' EOL { Spindle Orient }
SeqC AbsValue EOL
ELSE
SeqC OfstOff 'M19' EOL { Spindle Orient }
END
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
IF AbsoluteMoves?
SeqC IncValue OfstOff 'M19' EOL { Spindle Orient }
SeqC AbsValue EOL
ELSE
SeqC OfstOff 'M19' EOL { Spindle Orient }
END
END
END
RETURN
SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN
SameToolOp3: {Start new Operation}
G52Stuff
IF LAST ProgStop?
SeqC PlaneC Rapid AbsOrInc WFOStuff StrtPos CSAngleA CSAngleB SpeedC SpinOn EOL
SeqC CoolOn EOL
SeqC OfstOn EOL
ELSE
SeqC PlaneC Rapid AbsOrInc WFOStuff StrtPos CSAngleA CSAngleB SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
END
END
RETURN
End1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff SpinOff EOL { Spindle Orient }
ELSE
SeqC OfstOff SpinOff EOL { Spindle Orient }
END
RETURN
End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN
End3:
SeqC AbsValue 'M19' EOL { Spindle Orient }
SeqC 'G53X-15.Y0' EOL
{SeqC PreTool ToolChng EOL}
SeqC 'T' Add# Tool# Num#('1') ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN
NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN
{Start of executable Prog, Top Level ****}
ProgStart {setup and initializations}
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
Wyszukiwarka
Podobne podstrony:
Haas [HPD] BY68 15 2Haas [HPD] DY68 15 2Haas [ADB] CU70 15Haas [MP] DX77 15Haas [6D] MT11 15Haas [GH] MW96 15 2Haas [QC] D587 15 1Haas [QC] B587 15 1Haas [GV] BQ25 15Haas [SI] BX39 15Haas [HPD] MY68 13 6Haas [WMF] MZ27 15 3Haas [HA] MZ67 15Haas [VT] DQ69 15Haas [BMS] DU54 15Haas [Gimbel] MV90 15 1mwięcej podobnych podstron