{Change Comments ***********************************************************}
{added separate sub call code and warning for not separate, 7/5/88 WFG}
{separate sub calls turned off in this post- 'UseSeparateSubCalls' commented out}
{ncPost3ż24 or better}
{added IF ToolChangeAtHome?, & SetHome 9/26/88 WFG}
{added PostScript commands 3/11/89 WFG}
{added PostScript command comments 5/9/89, WFG, use ncPost 3.10Ś9 or better}
{removed run time comments, 5/9/89, WFG}
{added "must be all capital letters when typed in" to Postscript Command comment, 5/17/89, JR}
{added metric, 6/5/89, WFG}
{suppressed first cycle StrtPos for sep subs,7/17/89 WFG}
{last tool now goes to FirstHome when finished, 7/26/89, WFG}
{changed to Sep Sub standard}
{.65, corrected Sep sub problem if 1st cut <> Z step, 9/14/89 WFG, requires ncPost 3.19Ś5}
{.66, added name comment to Prog ID # line, 10/30/89, WFG}
{.67, new prog commands, 11/20/89, WFG}
{*.68, AutoCycles and 3.2 support, 12/4/89, WFG (Good luck on the upgrades to other posts)}
{.69, corrected 2 repeat op/autocycle problems, 12/21/89, WFG}
{1/8/90-2/7/90
Changes to M001.69
Moved DoPostScript command to very beginning of NewTool & SameTool op's, same as FirstOp.
Deleted last line of NewWFO PostScript comment, it no longer applies.
Move DoEndOpPS command in NewTool & end of prog to end of operation outside of Full-up MP.
Restucture to have M01 or M00 in New Tool.
Deleted ProgStop? from end of prog, not neccesary.
Check for ProgStop at beginning AND end of operation does not work, it comes out both places,
only using for end of operation. Reflected in PSComments.
Deleted StopProg sub.
Re-wrote SameTool section for many reasons.
Deleted ClearancePlane3# prog format it is no longer needed.
New sub CheckPass to replace statement in main for SetPass.
Modified WFOStuff sub to include SameTool.
Deleted StrtPos from OpenMP sub and added to main where needed.
Updated to .70 format.
Jim Radcliffe}
{.71.1, added InitProg, 4/11/90, JR}
{.71.2, FIRST modifier, no CRCOffC in AutoCycCutSub2, add Connect for ZOnlyRep, 4/23/90, JR}
{.72.1, New PS subs, formats, CoolOff?, ProgStop to start of NewTool & SameTool, 5/23/90, JR}
{.72.2, modified subroutine stuff (same effect), 7/1/90, DWB}
{.73, Replaced SetSRXYZero with SetSRXYtoSP, CoolOff, new formaters, 7/24/90, DWB}
{.74, ResetCRCNum, modified PostScript comments, 8/1/90, JR}
{.76, corrected AutoCycle SP and EP Status Record errors}
{.76.2, removed beginning Op ProgStop capability and Get Coolant, 2/6/91, WFG}
{2/15/91,
Updated to new 4.0 Version Fanuc 6M M001.80:
Added Coolant checking for SameTool.
Added ProgStop checking for final Operation.
DWB}
{5/17/91, M001.80.01 added drill Z's, WFG}
{9/13/91,
Modified: Fanuc 6M M001.80.01
Added IF FIFO? for Milling.
Added TrackZNO# ZDepth# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
DWB}
{7/24/92,
Modified: Fanuc 6M M001.81
Corrected FORMAT for Dwell# from '####^###;' to '####^##0'.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Changed FeedRateC to FeedEntC to FIFO Exit Moves.
Added RestoreScale Sub per 4-Axis Post Processor.
DWB}
{9/27/94
Copied & modified: Fanuc 6M M001.81.2
For: CIM Solutions / Advanced Machine
Control: Fanuc 0MC
Machine: Giddings & Lewis
Created Custom Processor per Sample Output and Comments.
Jim Radcliffe}
{5/1/95
Copied & modified: Fanuc 0MC G&L M696.81.2
For: Rands Systems Inc.
Control: Fanuc 0MC
Machine: Unknown
Created Custom Processor per Documents and Sample.
Marc Sickles}
{2/9/96, Updated .81 version to .84, MPK}
{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'(SUB NUMBER: ' Program# ')' EOL
END
RETURN
DoToolTypeComment:
IF UseComments? AND ToolTypeComment?
SetScale('1')
'(TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ')'
RestoreScale
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(OPERATION ' Operation# ': ' OperationType$ ')' EOL
END
IF OperationComment?
'(' OperationComment$ ')' EOL
END
IF WorkGroupComment?
'(' WorkGroupComment$ ')' EOL
END
RestoreScale
END
RETURN
DoToolComment:
IF UseComments? AND ToolComment?
'(' ToolComment$ ')' EOL
END
RETURN
PSInit: {reset flags}
NewWFOF
RotateF
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
ASCII('13') SubID EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT)' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC CRCOnC CRCOffsetC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC CRCOnC CRCOffsetC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC CRCOnC CRCOffsetC MoveXYZC FeedRateC EOL
END
END
RETURN
ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF LastFeat? AND NOT FirstFeat?
SeqC 'G98' MoveSXYZC EOL {Added for Rands -M Sickles}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN
WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
GetStartOfSameTool:
DoOpComments
DoToolTypeComment EOL
DoToolComment
DoPostScript
CheckPass
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('9999')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'(PROGRAM: ' ProgramName$ ')'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
SetScale('1') {restore scale for comments}
IF ProgramComment?
'(' ProgramComment$ ')' EOL
END
IF FormatNameComment?
'(FORMAT: ' FormatName$ ')' EOL
END
IF TimeComment?
'(' Date$ ' AT ' Time$ ')' EOL
END
IF MovesComment?
'(OUTPUT IN ' MoveType$ ' INCHES)' EOL
END
IF PartsComment?
'(PARTS PROGRAMMED: ' Parts# ')' EOL
END
IF StartToolComment?
'(FIRST TOOL NOT IN SPINDLE)' EOL
END
IF ToolTypeComment?
EachTool
SetFlag('1')
EachOp
IF Equal? TLNum# Tool#
IF Flag?('1')
SetFlagF('1')
'(TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ')' EOL
DoToolComment
END
END
NextOp
NextTool
END
RestoreScale
END
EachOp {Start of post processing *********************}
IF FirstOperation?
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
ASCII('13') 'N' Tool# Rapid Plane CRCOff WFOStuff 'G28G91Z0' EOL
SeqC ToolChng OpToolID EOL
DoOpComments
SeqC ProgStop DoToolTypeComment EOL
DoToolComment
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
DoPostScript
SeqC RapidC PlaneC AbsOrInc StrtPos EOL
SeqC Speed SpinOn EOL
SeqC OfstOn CoolOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
CoolOff ASCII('13') EOL
{Finish off last Operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
{SeqC OfstOff} {no offset cancel for Rands -M Sickles}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
{SeqC}
END
DoEndOpPS
SeqLab Tool# Rapid CRCOff 'G28' IncValue 'Z0M19' EOL
IF LAST ProgStop?
SeqC ASCII('13') 'M0' ASCII('13') EOL
END
IF ToolChangeAtHome?
SeqC AbsOrInc Home EOL
END
{Start new Operation}
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC ToolChng OpToolID EOL
SeqC ProgStop DoToolTypeComment EOL
DoToolComment
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
DoPostScript
SeqC WFOStuff EOL
SeqC RapidC PlaneC AbsOrInc StrtPos EOL
SeqC Speed SpinOn EOL
SeqC OfstOn CoolOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
ELSE
EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid CRCOff 'G28' IncValue 'Z0' EOL
SeqC 'M0' ASCII('13') EOL
{Start new Operation}
GetStartOfSameTool
SeqC RapidC PlaneC CRCOffC WFOStuff EOL
SeqC AbsOrInc StrtPos EOL
SeqC SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
IF NewToolOffset?
SeqC Rapid CRCOff 'G28' IncValue 'Z0' EOL
{Start new Operation}
GetStartOfSameTool
SeqC RapidC PlaneC WFOStuff AbsOrInc StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
{Start new Operation}
GetStartOfSameTool
SeqC RapidC PlaneC WFOStuff AbsOrInc StrtPos SpeedC EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC RapidC ZCP3C
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC
ELSE
SeqC RapidC CRCOffC ZCP3C
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF Tap?
SeqC 'M29' Speed EOL { synchronize spindle and Z axis }
END
SeqC Cycle FromCP StrtPos ZDepth FeedEnt RLevel Retract Peck Dwell EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
{SeqC 'G80' EOL} {Rands requested no 'G80' -M Sickles}
IF Repeats?
FinishSubG92
END
SeqC Rapid ZCP3C
END
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
{SeqC}
END
CoolOff ASCII('13') EOL
DoEndOpPS
SeqC Rapid CRCOff 'G28' IncValue 'Z0M19' EOL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC ASCII('13') 'M0' ASCII('13') EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(FILE LENGTH: ' FileBytes# ' CHARACTERS)' EOL
END
IF FileFeetComment?
'(FILE LENGTH: ' FileFeet# ' FEET)' EOL
END
IF FileMetersComment?
'(FILE LENGTH: ' FileMeters# ' METERS)' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 0MC G&L M696 87 1Fanuc 6M [MC] M710 87Fanuc 11M Okuma M124 87Fanuc 6MA Ooya M583 87Fanuc Series O Elox M234 87Fanuc 10M Kit 1 M151 87Fanuc 0MC [HBE] M926 89 1Fanuc 0MC Cin Sabre M978 89Fanuc 3000C Acroloc M066 87 1Fanuc 6M MTS M320 87Fanuc 0MC Jhnford M660 89Fanuc 0TC [Rands] L328 82 4Fanuc 6MB Kit M 3 M592 87Fanuc 0M [PP] M349 87Fanuc 0M [HM] M629 87więcej podobnych podstron