{Change Comments ***********************************************************}
{12/15/88 TF change XYZ from conditional, 'T0Z1.' from T0Z0}
{6/4/89 force EPs on arcs, and in proper planes, WFG}
{7/16/89 cust requests, for Visual Technics, also Metric, Postscript, multiple parts}
{7/27/89, G29 before all E's, WFG}
{9/11/89, repeats with weird origin shift WFG}
{9/14/89, fix SepSubs, WFG}
{10/30/89, shift of arc IJ's with long hand repeats & rapid/feed prob, WFG}
{10/30/89, needs 3.19alpha6 to run, WFG}
{4/20/90
Modified: Anilam Crusader (VT) M220.67
Re-Wrote drilling section to include more cycles & retract to ZCP1
Moved DoPostScript to before TCZ# command for proper operation.
Fix problem, missing G1 for RepZ op feed connect.
Jim Radcliffe}
{4/24/90, Update: Anilam Crusader (VT) M220.68 to .71.2 format, JR}
{4/27/90, Modified: Anilam Crusader (VT) M220.71.2, added 'ENGLISH' to Moves header comment, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{3/7/91
Modified: Anilam Crusader (VT) M220.72
Added ###.##;0. in the Default Formats dialog in the form, for FeedEnt and FeedRate.
There was no FORMAT for these two commands, and the result was a bunch of zeros on one line, and
all EOLs were ignored until ncPost exited ToolPath, and output the move to ZCP3.
DWB}
{4/03/91
Modified: Anilam Crusader (VT) M220.72.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}
{11/13/91
Modified: Anilam Crusader (VT) M220.79
For: Visual Technic
Added FORMAT #7 = '00' for TLNum# to output 4 digits at all times. And changed
the literal 'G29T100' to 'G29T0'.
Kim Michelman}
{03/18/92
Modified: Anilam Crusader (VT) M220.79.1
For: Visual Technic
Retyped the 'G29E' at the end of the prog, for some reason was only reading the 'E'.
Kim Michelman}
{03/19/92
Modified: Anilam Crusader (VT) M220.79.2
For: Visual Technic
Changed the EndSub in the form to read G29, and added a literal 'E' at the
end of the the subs being called and changed the literal 'G29E' at end of the program.
Kim Michelman}
{8/14/92
Modified: Anilam Crusader (VT) M220.79.3
For: Visual Technic
Changed PeckValue to Peck# and Formated to #2.
Changed the Dwell# Format to #2.
Updated the PSStuff.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}
{9/18/92
Modified: Anilam Crusader (VT) M220.81.1
For: Visual Technic
Added OptCyc1 boolean for postscript. Customer requested 'M1000' & 'M2000'.
Kim Michelman}
{7/2/93
Copied & modified: Anilam Crusader (VT) M220.81.3
For: Visual Technic
Modified FormatArc ao that arcs whose segment height is less than .0005
get output as a linear move.
Jim Radcliffe}
{2/4/94
Copied & modified: Anilam Crusader (VT) M220.81.4
For: CNCCS / Polo Metal Fab
Changed 'N0' on first line in program to Seq.
Changed 'Z' TLLength# in EachTool/NextTool loop, and all 'Z' ToolLength# to literal 'Z0',
note that these are the only literal Z0s in the prog if you want to change them back.
Changed default for TCZ# from 3.5 to 0.
Modified output of home to move Z home before move XY Home.
Added SpinOn and SpinOff commands.
Added CoolOn and CoolOff commands.
Moved ZCP1 to aaded line following StrtPos.
Deleted 'G1' from ZDepth line in Drilling.
Misc update changes, corrections etc, could probably still use more!
Changed tab to space in drilling cycles.
Jim Radcliffe}
{3/29/94, added support for Virtual Tap & Rigid Tap, JR}
{3/29/94, changed Seq to SeqLab & added Retag to get consecutive sequence numbers, JR}
{4/12/96
Copied & modified: Anilam Crusader (PMF) M645.81.3 to Anilam Crusader (S) M000.00
For: Simonz.
Added M1000 to milling operations after Z cut depth move, and M2000 before raising Z from
cut depth. As required by this NC Control.
KC}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '###.####;0'
#5 = '#######0'
#6 = '00'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Dwell#,4)
FORMAT(TLDia#,4)
FORMAT(TLLength#,4)
FORMAT(TCZ#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(FeedEntry#,4)
FORMAT(CurOriginPosX#,4)
FORMAT(CurOriginPosY#,4)
FORMAT(Peck#,4)
FORMAT(Tag#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(TLNum#,6)
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags}
RotateF
OptCyc1F { Reset Rigid Tap flag }
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN
StartSub:
OpenSub
DoSubComment
SeqLab 'G29S' Tag# EOL
RETURN
EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
SeqLab 'M1000' EOL {M1000}
ELSE
SeqLab RapidC ZIn EOL
SeqLab 'M1000' EOL {M1000}
END
RETURN
SubWarning:
IF NOT FeedConnect? AND UseComments?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
IF MultipleParts? OR AnyZShift?
IF UseComments?
'( THIS REPEAT OP WILL BE LONGHAND DUE TO MULT PARTS OR Z SHIFT)' EOL
END
EachRep {can't nest origin shifts or origin shift Z}
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL
END
ELSE
NewProg TagInc
EachRep
IF NOT FirstCycle?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z0' EOL
END
SeqLab 'G29C' Tag# EOL
NextRep
StartSub
SeqLab AbsOrInc Connect StrtPos EOL
END
RETURN
FinishSub1: {part 1}
SeqLab 'M2000' EOL
SeqLab CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
IF MultipleParts? OR AnyZShift?
NextRep
ELSE
SeqLab 'G29E' EOL
CloseSub
SeqLab 'M1101' EOL
SeqLab 'X0Y0Z0' EOL
END
RETURN
OpenMP1T:
NewProg TagInc
EachPart
IF NOT FirstPart?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z0' EOL
END
SeqLab 'G29C' Tag# EOL
NextPart
StartSub
SeqLab Rapid StrtPos EOL
RETURN
OpenMPAT:
EachPart
RETURN
CallMPAT:
IF NOT FirstPart?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z0' EOL
ELSE
NewProg {firstPart only, 1 per tool}
END
TagInc
SeqLab 'G29C' Tag# EOL
IF FirstPart?
StartSub
SeqLab Rapid StrtPos EOL
DoOpComments
END
RETURN
CloseMP1T:
SeqLab 'G29E' EOL
CloseSub
RETURN
RetMPAT:
SeqLab 'G29E' EOL
CloseSub
RETURN
CloseMPAT:
NextPart
RETURN
ArcSegHeight#:
MUL# ArcR# SUB# Num#('1') COS# DIV# ArcAngle# Num#('2')
RETURN
FormatArc:
IF LessThan? ArcSegHeight# Num#('.0005')
FeedC {output a linear move}
ELSE
IF ArcCW?
CWArc
ELSE
CCWArc
END
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveZ MoveYC
ELSE
MoveY MoveZ MoveXC { YZ plane }
END
END
IF LessThan? ArcSegHeight# Num#('.0005')
{we are outputting a linear move}
ELSE
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN
ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab 'G29C' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Tap? AND OptCyc1? { Rigid Tap uses subs}
SeqLab MoveSXYC EOL
SeqLab 'G29C' Tag# EOL
ELSE
SeqLab MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF OptCyc1?
IF Flag?('1')
SetFlagF('1')
END
END
IF LastFeat? AND AutoCycle? {.70}
SeqLab CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF OptCyc1?
IF Flag?('1')
{M1000 is currently on}
ELSE
SetFlag('1')
SeqLab 'M1000' EOL {turn on look ahead}
END
END
IF AutoCycle? {.70}
IF LastFeat?
SeqLab CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
IF OptCyc1?
IF Flag?('1')
{M1000 is currently on}
ELSE
SetFlag('1') {turn on look ahead}
SeqLab 'M1000' EOL
END
END
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab CRCOnC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab CRCOnC FormatArc DecelFeed EOL
ELSE
SeqLab CRCOnC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
IF OptCyc1?
IF Flag?('1')
SetFlagF('1')
END
END
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
SeqLab StrtPosC EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLab AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLab AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLab AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqLab EndSub 'E' EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN
Milling:
IF AutoCycle?
NewProg TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
NewProg TagInc
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg TagInc
SetPass1 {for correct Z's}
EachCycle
IF FeedConnect?
SeqLab Feed ZInPlusInc FeedEnt EOL
SeqLab 'M1000' EOL {M1000}
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
SeqLab 'M1000' EOL {M1000}
ELSE
SeqLab Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
SeqLab 'M1000' EOL {M1000}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab 'G29C' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLab Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLab 'G29E' EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
NewProg TagInc
EachCycle
IF FeedConnect?
IF NOT FirstCycle?
SeqLab Feed StrtPos EOL
END
SeqLab FeedC ZInPlusInc FeedEnt EOL
SeqLab 'M1000' EOL {M1000}
ELSE
IF NOT FirstCycle?
SeqLab Rapid StrtPos EOL
END
IF FeedEntry?
IF NOT FirstCycle?
SeqLab ZCP2PlusIncC EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
SeqLab 'M1000' EOL {M1000}
ELSE
SeqLab ZInPlusInc EOL
SeqLab 'M1000' EOL {M1000}
END
END
SeqLab 'G29C' Tag# EOL
NextCycle
SetStatusRapid {force next G1,G2,G3,etc.}
StartSub
SkipZ
ToolPath
UnSkipZ
FinishSub1
SeqLab 'G29E' EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls ('1000')
SetTCZ('0')
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetFlagF('1')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' TCZ(), TOOLCHANGEZ() -' EOL
' Set the Toolchange Z value. Modal, changes all following OPs.' EOL
' Value is set to Z0 as a default.' EOL
' OptCyc1, OptionalCycle1 -' EOL
' For the selected operation to use look ahead.' EOL
END
IF MultipleParts? AND AllToolsOnePart?
OpenMPAT
TagInit
END
EachOp
IF FirstOperation?
IF FirstPart?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqLab Rapid Plane 'G70' AbsValue EOL
EachTool
SeqLab 'G29T10' TLNum# 'X' TLDia# 'Z0' EOL
NextTool
SeqLab 'T0' EOL
DoPostScript
IF ToolChangeAtHome?
SeqLab 'Z' TCZ# EOL
SeqLab Home EOL
ELSE
SeqLab 'Z' TCZ# EOL
END
END {end firstPart?}
IF MultipleParts? AND AllToolsOnePart?
CallMPAT {has DoOpComments}
ELSE
DoOpComments
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP1T
END
IF FirstPart?
SeqLab OpToolID EOL
SeqLab SpinOn EOL
SeqLab CoolOn EOL
CheckPass
SeqLab AbsOrInc StrtPos EOL
SeqLab 'Z' ClearancePlane1# EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP1T
END
END {end firstPart?}
ELSE
IF NewTool?
{Finish off last Operation}
IF FirstPart?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP1T
END
SeqLab SpinOff EOL
SeqLab CoolOff EOL
SeqLab 'T0' EOL
SeqLab 'Z' TCZ# EOL
DoEndOpPS
END {end firstPart?}
IF MultipleParts?
IF OneToolAllParts? AND FullUp?
CloseMP1T
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
ELSE
IF AllToolsOnePart?
IF FirstPart?
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
RetMPAT
END {end firstPart?}
ELSE
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
END
END
ELSE
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
END
IF LAST ProgStop?
SeqLab 'G4' EOL
ELSE
SeqLab ProgStop EOL
END
{Start new Operation}
IF FirstPart?
DoPostScript
END
IF MultipleParts? AND AllToolsOnePart?
CallMPAT {has DoOpComments}
ELSE
DoOpComments
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP1T
END
IF FirstPart?
SeqLab OpToolID EOL
SeqLab SpinOn EOL
SeqLab CoolOn EOL
CheckPass
SeqLab Plane Rapid StrtPos EOL {add plane}
SeqLab 'Z' ClearancePlane1# EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP1T
END
END {end firstPart?}
ELSE
IF SameTool? AND FirstPart?
DoEndOpPS
IF LAST ProgStop?
SeqLab SpinOff EOL
SeqLab CoolOff EOL
SeqLab 'G4' EOL
{Start new Operation}
GetStartOfSameTool
SeqLab SpinOn EOL
SeqLab CoolOn EOL
SeqLab Plane Rapid StrtPos EOL {add plane}
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset?
{Start new Operation}
GetStartOfSameTool
SeqLab Plane Rapid StrtPos EOL {add plane}
ELSE
{Start new Operation}
GetStartOfSameTool
SeqLab Plane Rapid StrtPos EOL {add plane}
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
END
END
END
IF FirstPart?
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLab FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLab 'M2000' EOL
SeqLab RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
SubWarning
StdSub
END
SeqLab DrillCP EOL
GetCycle
IF Tap? AND OptCyc1? { Rigid Tap }
NewProg TagInc
OpenSub
SeqLab 'G29S' Tag# EOL
SeqLab Feed ZDepth 'F' FeedEntry# EOL
SeqLab SpinOff EOL
SeqLab InverseSpinOn EOL
SeqLab 'Z' ClearancePlane2# EOL
SeqLab SpinOff EOL
SeqLab SpinOn EOL
SeqLab Rapid EOL
SeqLab 'G29E' EOL
CloseSub
ToolPath
ELSE
IF RetractToCP1?
SeqLab 'M1313' EOL
END
SeqLab 'G29LV20 ' FeedEntry# EOL
SeqLab 'G29LV21 ' ClearancePlane2# EOL
IF Dwell?
SeqLab 'G29LV22 ' Dwell# EOL
END
IF Peck?
SeqLab 'G29LV23 ' Peck# EOL
END
IF RetractToCP1?
SeqLab 'G29LV24 ' ClearancePlane1# EOL
END
IF FIFO? AND Dwell?
SeqLab 'G89' EOL
ELSE
SeqLab Cycle EOL
END
SeqLab ZDepth EOL
SeqLab StrtPos EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqLab 'G80' EOL
IF RetractToCP1?
SeqLab 'M1314' EOL
END
END
IF Repeats?
FinishSubG92
END
SeqLab RapidC ZCP3C EOL
END
END
END
NextOp
IF FirstPart?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP1T
END
SeqLab SpinOff EOL
SeqLab CoolOff EOL
SeqLab 'T0' EOL
SeqLab 'Z' TCZ# EOL
DoEndOpPS
END {end firstPart?}
IF MultipleParts?
IF OneToolAllParts? AND FullUp?
CloseMP1T
IF FIRST ToolChangeAtHome?
SeqLab Rapid FirstHome EOL
END
ELSE
IF AllToolsOnePart?
IF FirstPart?
IF FIRST ToolChangeAtHome?
SeqLab Rapid FirstHome EOL
END
RetMPAT
END {end firstPart?}
ELSE
IF FIRST ToolChangeAtHome?
SeqLab Rapid FirstHome EOL
END
END
END
ELSE
IF FIRST ToolChangeAtHome?
SeqLab Rapid FirstHome EOL
END
END
IF ProgStop?
SeqLab 'G4' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMPAT
END
SeqLab EndSub 'E' EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Anilam Crusader II G&C M995 89Anilam Crus II [SU] M562 81 2Anomatic II Anorad M406 81 3Anilam Crusader [USS] M195 89BP Boss 6 Ser II [NM] M549 81 3Anilam Ser 1400 Tree M727 81 2Anilam Crusader 2 M158 81mAnilam Crusader L051 82Anomatic II Anorad M406 81 3mAnilam Crusader (VT) M220 87mAnilam Crusader 2[MD] M463 89Anilam Crusader 2 L231 82więcej podobnych podstron