{Change Comments ***********************************************************}
{8/11/89, Updated processor JR}
{8/31/89, Added PostScript, JR}
{12/1/89, Updated: Fanuc 11M M007.61, JR}
{2/7/90, Updated to Version 3.2 per Fanuc 6M M001.70 Format, DWB}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{9/28/90, Updated: Fanuc 11M M007.71 to .76.1 format, JR}
{10/23/90
Copied & modified: Fanuc 11M M007.76.1
For: Chndler Evans (Colt Ind.)
Machine: Matsuura/Beaver Mill
Change G70 to G20 at prog start-up.
Add AbsOrInc command to WFO line.
Add line at beginning of 1st tool: /G91G28X0.Y0.Z0.M19
Change tool change position to: /G91G28X0.Y0.M19
Jim Radcliffe}
{11/11/91
Modified: Fanuc 11M Matsuura M353.81
For: Chandler Evans
Removed wrongly placed 'END' in IF SameTool? Section after the IF NewToolOffset?
Kim Michelman}
{
11/25/94
Modified: Fanuc 11M Matsuura M353.81.1
For: Peterson Machine
Added empty line with sequence number before all tool changes
All I's and J's converted to R's, except on a full radius
Places all operations into sub-routines. Ops using the same tool are in the same sub.
Added empty line between all sub programs
Moved optional block skip to be con tool change lines only.
Moved spindle on/off outside of sub programs
Moved coolant on/off outside of sub programs
Changed comments output at start of program
Changed output of tool change comment
Change output of sub-program comment
Added D command for cutter comp at each tool change
Added G90G80G40G49G00 after every tool change
Removed /G91G28X0.Y0.M19 (From 10/23/90 change).
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.3
For: Peterson Machine
Reversed order of G81 amd G99 in drill cycle
Made output of first hole XYZ in drill cycle conditional.
Fixed IJ circle output for full radius circles.
Replaced OfsStOff command with G28X0Y0Z0
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.4
For: Peterson Machine
Replaced literal G90s with AbsValue
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.5
For: Peterson Machine
Added WFOStuff to StartPos line in NewTool?
Removed IF MultipleParts? call WFOStuff blocks in NewTool?
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.6
For: Peterson Machine
5/22/95
Changed format of P to ####^000; for proper dwell output
Added WFOStuff on line by itself after 'G90G80G40G49G00' line
Replaced OfstOff command at end of prog with 'G28X0Y0Z0'
Replaced CallLab with 'P' Program#
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.7
For: Peterson Machine
6/8/95
Removed WFOStuff from end of NewTool
TH}
{
Format: Fanuc 11M Mat [PM] M716.81.8
For: Peterson Machine
10/4/95
Updated to new prog style
Changed multiple parts to place sub calls into main program
Set up so WFO1 is called out in all MP loops
Changed OpenMP so G54 is not output
TH}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^000;0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags}
NewWFOF
RotateF
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN
StartOpSub:
OpenSub
ASCII('13')
SubID EOL
'( SUB TO: ' Program2# ' MAIN )' EOL
'( ' ToolDiameter# ' ' ToolType$ ' )' EOL
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC SubCall 'P' Program# RepLab RepCycs EOL
StartSub
RETURN
OpSub:
SeqC SubCall 'P' Program# EOL
StartOpSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedRateC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
SeqC SubCall 'P' Program# RepLab OnePart EOL
IncWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall 'P' Program# RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC SubCall 'P' Program# RepLab Parts EOL
END
StartSub
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
CRCOnC
IF NOT EmptyLine?
ResetCRCNum
END
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN
ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall 'P' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedRateC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall 'P' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall 'P' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SaveProgNum2
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' CoolantOff, COff -' EOL
' suppress coolant on command for current operation' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' ProgramStop, PS' - EOL
' Coolant Off, full tool up, M00, restore tool postion, coolant on.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN
OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC FromCP Cycle StrtPosC ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
{ SeqC RapidC ZCP3C EOL}
END
END
RETURN
NotSameToolWFO:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC 'G' NewWFO# EOL
ELSE
IF NeedWFO1?
SeqC 'G' NewWFO# EOL
END
END
END
RETURN
SameToolWFO:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC 'G' NewWFO# EOL
END
END
RETURN
InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
{ IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
} IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
END
OpenSub
RestoreScale
RETURN
FirstOp1:
Seq ASCII('13')
SeqC '/' OpToolID ToolChng
IF ToolTypeComment?
'( 'ToolDiameter# ' ' ToolType$ ' )' EOL
END
SeqC ProgStop EOL
Plane {No output}
SeqC AbsValue 'G80G40G49G00' EOL
DoPostScript
RETURN
FirstOp2:
SeqC OfstOn SpinOn Speed EOL
SeqC CoolOn CRCOffsetC EOL
RETURN
FirstOp3:
CheckPass
SeqC AbsValue Rapid StrtPos EOL
RETURN
FirstOp3a:
CheckPass
RETURN
NewToolOp1:
SeqC Rapid ZCP1C SpinOff EOL
SeqC IncValue 'G28X0Y0Z0' CoolOff EOL
RETURN
NewToolOp2:
DoEndOpPS
RETURN
NewToolOp3:
Seq ASCII('13')
SeqC '/' OpToolID ToolChng
IF ToolTypeComment?
'( ' ToolDiameter# ' ' ToolType$ ' )'
END
EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
Plane {No output}
SeqC AbsValue 'G80G40G49G00' EOL
RETURN
NewToolOp4:
SeqC OfstOn SpinOn Speed EOL
SeqC CoolOn CRCOffsetC EOL
DoPostScript
RETURN
NewToolOp5:
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN
NewToolOp5a:
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN
SameToolOp1:
DoEndOpPS
SeqC Rapid ZCP1C EOL
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue 'G28X0Y0Z0' EOL
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff EOL
END
END
RETURN
SameToolOp2: {Start new Operation}
DoPostScript
CheckPass
RETURN
SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC CoolOn CRCOffsetC EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
SeqC
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
CRCOffsetC EOL
END
RETURN
End1:
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
RETURN
End2:
SeqC Rapid ZCP1C SpinOff EOL
SeqC IncValue 'G28X0Y0Z0' CoolOff EOL
RETURN
End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp
IF FirstOperation?
InitOp
OpenMP
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
CloseMP
End3
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp
IF FirstOperation?
InitOp
FirstOp1
SeqC WFO1 EOL
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2
NewToolOp3
SeqC WFO1 EOL
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
CloseMP
End2
End3
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp
IF FirstOperation?
InitOp
FirstOp1
SeqC WFO1 EOL
FirstOp2
FirstOp3a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2
NewToolOp3
SeqC WFO1 EOL
NewToolOp4
NewToolOp5a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
CloseMP
End1
End2
End3
RETURN
NoMPs: {no multiple parts}
EachOp
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
NewProg
OpSub
FirstOp3
ELSE
IF NewTool?
FinishSub1
SeqC EndSub EOL
CloseSub
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewProg
OpSub
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END
OpGuts
NextOp
End1
FinishSub1
SeqC EndSub EOL
CloseSub
End2
End3
RETURN
{Start of executable Prog, Top Level ****}
ProgStart {setup and initializations}
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
Wyszukiwarka
Podobne podstrony:
Fanuc 11M Mat [PM] M716 10 1Fanuc 11M Mat [AM] C820 16Fanuc 11M Mat 600 C199 12Fanuc 6M Mat MC1000V M474 81 1Fanuc 11M Mat 1500 M702 89Fanuc 11M AS KM1800 M092 81 2Fanuc 11M Enshu [DF] M729 81 2Fanuc 11M Mat [AM] RM820 17 5Fanuc 11M Wasino [CD] M624 81 2Fanuc 3000C Mat LH PM M495 89 3Fanuc 11M (2) M146 81Fanuc 11M [WTG28] M475 81 1Fanuc 11M Matsuura M353 81 1Fanuc 11M Varnsdorf M769 81 2Yas MX3 Mat [AbsZAC] M591 81 2Fanuc 11M [TM] CQ07 16 2Fanuc 11M MS [HM] M433 80więcej podobnych podstron