{Prog Comments ****}
{
10/21/94 [cwh]
M689.82
Updated to new post prog format.
11/29/94 [ws]
Cin Acr A2100 M689.82.02 ( from M689.82.01 )
Modified so 'W' value posted on all drill lines based on "W = zretract - top surface"
Modified drilling 'R' value to be top surface via CalcZSurf#
11/30/94 [ws]
Cin Acr A2100 M689.82.03 ( from M689.82.02 )
Modified G80 line to include a 'R' value where R = zretract.
1/3/95 [ws]
Cin Acr A2100 M689.82.04 ( from M689.82.03 )
Modified so 'Z' value for drilling is calculated as "Z = Tip Depth - Top Surface"
Modified so when using Post Script command for coolant change coolant reset back to the original
2/15/95 [ws]
Cin Acr A2100 M689.82.05 ( from M689.82.04 )
Modified so output H word is not on a line by itself. (affects how MP NC code is output)
2/17/95 [ws]
Cin Acr A2100 M689.82.06 ( from M689.82.05 )
Modified so subroutine labels are reinitialized on reprocessing.
Modified "M02M52" end of Program statement to "M26M02"
7/11/95 [ws]
Cin Acr A2100 M689.82.07 ( from M689.82.06 )
Modified so Rigid Tap has no R word on G80 cycle.
Modified so Spindle Speed is on Rigid Tap Block.
Modified so M code is on the Rigid Tap Block.
7/13/95 [ws]
Cin Acr A2100 M689.82.08 ( from M689.82.07 )
Modified Rigid Tap and Tap blocks to use G95 (feed / rev ) and cancel with G94 after G80 block
to restore back to Feed/Minute.
}
{1/17/96, Updated .85 to .86 version, MPK}
{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}
{5/29/96,
Initial: Cin Acr 850SX Sabre M689.12
Created: Cin Acr 850SX Sabre M689.12.1
For: Gibbs & Associates
Changed to no longer use tagging, changed GetIndex sub to PSStuff per M001, eliminated all references to GetIndex, added calls
to PSStuff per M001, eliminated many sections of code that were commented out to cut done on prog clutter. Overhauled
OpenMP: eliminated use of Flags, added support for full up for multiple parts with work fixture offsets, post should now
work with equally spaced offsets, see comments in prog for more info. Added support in CloseMP for full up with
Equally spaced Offsets. Made changes to the multiple parts case subs to accomodate changes to OpenMP and CloseMP.
Eliminated need for FirstOp3a and NewToolOp5a. Standardized use of RestoreAbsOrInc, per M001, eliminated
NotSameToolWFO, SameToolWFO, RestoreAbs, SubCSMP, FirstOp3b, NewToolOp5b subs, added output of WFO to FirstOp3
and NewToolOp5, completed update to compliance with 2.20. MPK}
{10/12/97,
Created Metric Version...CDH }
{12/9/97,
Initial : Cin Acr 850SX Sabre M689.12.1m
Created: Cin Acr 850SX [AP] MW67.12m
Customer: Axis Precision (n.z.)
Changes to "Prog":
1. Added SeqLabC at all MSG blocks.
2. Added :G0 to tape start.
3. Changed Tool Change block and added /M1 block.
4. Changed output after TC to output Speed (S___) SpinON (M3) & DoCoolOn (M8) in 1st block,
G61 DoAbsOrInc (G90) Rapid (G0) X & Y in 2nd block, and Z in 3rd block.
5. Changed Tape End output.
6. Revised the output of Tap & RigidTap cycles.
7. Revised the output after all canned cycles (with G80).
JHE}
{Prog Numeric Format Definitions ********************************}
#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '#####.###;0'
#5 = '#######0'
#6 = '##.##;0'
#7 = '0000'
#8 = '+#####.###;0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CP1LessCP2#,4)
FORMAT(ADD#,4)
FORMAT(SUB#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(CalcZSurf#,4)
FORMAT(ToolDiameter#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(Repeats#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(HelixPitch#,8)
{Prog Subroutines ****************}
RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
DoCoolOn:
IF ThruSpin?
'M27'
ELSE
CoolOn
END
RETURN
PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
ResetCool
MasterOpF
CallMasterOpF
RETURN
PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree#
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree#
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree#
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree#
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
'(DFS,L' Program# ')' EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqLabC 'G10=[T2]V0' EOL {sets temporary register #2 to 0}
SeqLabC 'Q' Program# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Program# ')' EOL {call subroutine}
SeqLabC 'G10=[T2]V[T2]+1' EOL {increment register #2 by 1}
SeqLabC 'G11E[T2]=' Repeats# 'L' Program# '2' EOL {if register #2 is equal to number of repeats then jump to branch label 2}
SeqLabC 'G11L-' Program# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Program# '2' EOL {branch label 2}
StartSub
RETURN
FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
IF AllToolsOnePart?
DoOpComments {The next eight lines take the place of FirstOp1and FirstOp2 for AllToolsOnePart }
DoPostScript
':T' Tool# ToolChng EOL {Removed ?' Plane 'G71' AbsOrInc Rapid - JHE}
'/M1' EOL {Added this line - JHE}
IF AutoCycle? {This takes palce of the CheckPass sub in FirstOp2}
SetPass2
ELSE
SetPass1
END
END
IF OneToolAllParts? AND FullUp? AND GreaterThan? PartNum# Num#('1') {Does not send spindle full up on first part}
SeqLabC 'M26' EOL {Sends tool full up}
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC Rapid StrtPos EOL {Removed PlaneC - JHE}
SeqLabC ZCP1 SetWFO EOL {Removed Speed SpinOn - JHE}
ELSE
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC Rapid StrtPos EOL {Takes the place of FirstOp3 (and 3a) and NewToolOp5 (and 5a) for all multiple parts cases, except NewToolOp5 in the case of AllToolsOnePart }
SeqLabC ZCP1 SetWFO EOL {Added this line - JHE}
END {Removed PlaneC ZCP1 Speed SpinOn SetWFO from Rapid line - JHE}
{ IF AllToolsOnePart? Moved DoCoolOn with SpinOn - JHE
SeqLabC DoCoolOn EOL
ELSE
IF EQUAL? PartNum# Num#('1')
SeqLabC DoCoolOn EOL
END
END }
SeqLabC '(CLS,L' Program# ')' EOL
IncWFO
NextWFO
ELSE
SeqLabC 'G10=[T1]V0' EOL
SeqLabC 'Q' Program# '1' EOL
IF NOT AllToolsOnePart?
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC 'G61' AbsOrInc Rapid StrtPos EOL {Removed ZCP1 Speed SpinOn 'H' NewWFO#, Added 'G61' AbsOrInc - JHE}
SeqLabC ZCP1 EOL {Added this line - JHE}
{SeqLabC DoCoolOn EOL} {Removed this line - JHE}
END
SeqLabC '(CLS,L' Program# ')' EOL
SeqLabC 'G10=[T1]V[T1]+1' EOL
SeqLabC 'G11E[T1]=' Parts# 'L' Program# '2' EOL
SeqLabC 'G11L-' Program# '1' EOL
SeqLabC 'Q' Program# '2' EOL
END
StartSub
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqLabC '(ENS)' EOL
CloseSub
ELSE
SeqLabC Preset ShiftPC EOL
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL
SeqLabC StrtPos EOL
END
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN
ckHMove:
SetStatusOff
SetFlagF('9')
IF YZPlane?
IF NotEqual? SUB# SPY# ArcI# SUB# ArcI# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPX# ArcI# SUB# ArcI# EPX#
SetFlag('9')
END
END
SetStatusOn
RETURN
ckVMove:
SetStatusOff
SetFlagF('9')
IF XYPlane?
IF NotEqual? SUB# SPY# ArcJ# SUB# ArcJ# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPZ# ArcJ# SUB# ArcJ# EPZ#
SetFlag('9')
END
END
SetStatusOn
RETURN
ckMove:
IF NOT FullArc?
IF XYPlane? AND NOT ZMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT YMove?
ckHMove
END
END
ELSE
IF XZPlane? AND NOT YMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
ELSE
IF YZPlane? AND NOT XMove?
IF NOT YMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
END
END
END
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ ArcIJ 'K' HelixPitch#
ELSE
MoveX MoveY ArcIJ
END
ELSE
{ ??? what about incr subs here ??? }
IF XZPlane?
IF YMove?
MoveX MoveY MoveZ ArcIJ 'J' HelixPitch#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveX MoveY MoveZ ArcIJ 'I' HelixPitch#
ELSE
MoveY MoveZ ArcIJ
END
END
{ ??? }
END
RETURN
CkCRC:
IF LastFeat? { Exit Length Feature }
CRCOffC
ELSE
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
END
RETURN
StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYZC FeedRateC EOL { CRCOffsetC }
DecelMove2
END
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYZC DecelFeed EOL { CRCOffsetC }
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYZC FeedRateC EOL { CRCOffsetC }
END
END
RETURN
ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS,L' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Drilling?
IF SPXMove? OR SPYMove? OR SPZMove?
SeqLabC DoDrillAbsOrInc MoveSXYZC
IF RetractToCP1?
IF NotEqual? SUB# ClearancePlane1# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane1# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane1# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ClearancePlane2# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane2# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane2# CalcZSurf#
END
END
END
EOL
END
ELSE
SeqLabC MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF AutoCycle?
SeqLabC DoAbsOrInc
IF LastFeat?
CRCOffC
END
RapidC MoveXYZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC
END
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
ckMove
IF Flag?('9')
SetFlagF('9')
StdLine
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
IF LastFeat? AND CutterRadiusCompensation? AND NOT AutoCycle?
CRCOffC
IF NOT EmptyLine?
SeqLabC DoAbsOrInc LastFeatExtend EOL { ??? any zmoves ??? }
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC '(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,L' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC '(ENS)' EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
SetFlagF('2')
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqLabC '(CLS,L' Program# ')' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC '(ENS)' EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN
SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC PlaneC
IF FIFO? AND Dwell? {Bore/Ream with Dwell}
'G89'
ELSE
Cycle
{IF Tap? {Removed output of G95 - JHE}
'G95' {switch to Feed per Revolution units}
END }
END
StrtPos
'Z' Sub# Add# ClearancePlane2# Zdepth# CalcZSurf# { Z = tip depth - Top Surface}
'R' CalcZSurf#
IF RetractToCP1?
IF NotEqual? SUB# ClearancePlane1# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane1# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane1# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ClearancePlane2# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane2# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane2# CalcZSurf#
END
END
END
Peck
IF RigidTap? {Added this check - JHE}
'K' FeedTapIPR#('3') 'P1.5'
END
{IF Peck? {Removed 2 lines - JHE}
FeedEnt }
IF PeckFullRetract? OR RigidTap? {Changed from PeckChipBreaker? and added RigidTap? - JHE}
'J1' {Changed from 'J0' - JHE}
ELSE
IF PeckChipBreaker? {Added this check - JHE}
'J0' {Changed from 'J1' - JHE}
END
END
FeedEnt EOL {Added this line - JHE}
{ELSE {Removed next 11 lines - JHE}
IF RigidTap?
'F' FeedTapIPR#('1') Speed SpinOn 'J1'
ELSE
IF Tap?
'F' FeedTapIPR#('1')
ELSE
FeedEnt
END
END
END
EOL }
IF CallMasterOp?
SeqLabC '(CLS,L' CallMasterNum# ')' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC '(CLS,L' Program# ')' EOL
StartSub
ToolPath
SeqLabC '(ENS)' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF RigidTap?
SeqLabC DrillOff 'J0' EOL
{SeqLabC 'G94' 'F1.'} {Removed this line - JHE}
ELSE
SeqLabC DrillOff EOL
{IF RetractToCP1? {Removed next 8 lines - JHE}
'R' ClearancePlane1#
ELSE
'R' ClearancePlane2#
END
IF Tap?
EOL
SeqLabC 'G94' 'F1.'
END }
END
SeqLabC Rapid ZCP3 EOL {Changed ZCP3C to ZCP3 - JHE}
IF Repeats?
FinishSubG92
END
END
END
SetFlagF('2')
RETURN
InitOp:
EOR EOL
':G0' EOL {Added this line - JHE}
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLabC '(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
SeqLabC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLabC '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
SetProgNum('0')
OpenSub
RestoreScale
RETURN
FirstOp1:
DoOpComments
DoPostScript
':T' Tool# ToolChng EOL {Removed ?' Plane 'G71' AbsOrInc Rapid - JHE}
'/M1' EOL {Added this line - JHE}
RETURN
FirstOp2:
CheckPass
RETURN
FirstOp3:
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC 'G61' AbsOrInc Rapid StrtPos EOL {Removed ZCP1 Speed SpinOn 'H' NewWFO#, Added 'G61' AbsOrInc - JHE}
SeqLabC ZCP1 EOL {Added this line - JHE}
{SeqLabC DoCoolOn EOL} {Removed this line - JHE}
RETURN
FirstOp3a:
{FirstOp3a stuff done in OpenMP}
RETURN
NewToolOp1:
RETURN
NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN
NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
':T' Tool# ToolChng EOL {Removed ?' Plane 'G71' AbsOrInc Rapid - JHE}
'/M1' EOL {Added this line - JHE}
RETURN
NewToolOp4:
CheckPass
RETURN
NewToolOp5:
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC 'G61' AbsOrInc Rapid StrtPos EOL {Removed ZCP1 Speed SpinOn, Added 'G61' AbsOrInc - JHE}
SeqLabC ZCP1 EOL {Added this line - JHE}
{IF NOT MultipleParts? {Removed next 9 lines - JHE}
'H' NewWFO#
ELSE
IF NOT WorkFixtureOffsets?
'H' NewWFO#
END
END
EOL
SeqLabC DoCoolOn EOL }
RETURN
NewToolOp5a:
{NewTool5a stuff done in OpenMP}
RETURN
SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
{ does not cancel tool offsets, Full up for multiple parts done in CloseMP , MPK 5/28/96 }
END
END
RETURN
SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN
SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLabC Speed SpinOn DoCoolOn EOL {Added this line - JHE}
SeqLabC Rapid StrtPos EOL {Removed PlaneC ZCP1 Speed SpinOn - JHE}
SeqLabC ZCP1 EOL {Added this line - JHE}
{SeqLabC DoCoolOn EOL} {Removed this line - JHE}
ELSE
IF NewToolOffset?
SeqLabC Rapid StrtPos SpeedC EOL {Removed PlaneC ZCP1 - JHE}
SeqLabC ZCP1 EOL {Added this line - JHE}
ELSE
SeqLabC Rapid StrtPos SpeedC EOL {Removed PlaneC - JHE}
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC DoCoolOn EOL
END
END
RETURN
End1:
RETURN
End2:
DoEndOpPS
SeqLabC 'G60' EOL {Added this line - JHE}
SeqLabC 'M19' CoolOff EOL {Added this line - JHE}
SeqLabC 'M26' EOL {Z Axis Full Retract}
IF FIRST ToolChangeAtHome?
SeqLabC Rapid FirstHome EOL {Removed AbsOrInc - JHE}
ELSE
SeqLabC 'G98Y510.' EOL {Added this line - JHE}
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN
End3:
SeqLabC 'M52M2' EOL {Changed M26 to M52 - JHE}
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
EOR EOL
Close
ReTag
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
IF WorkFixtureOffsets?
{FirstOp1 FirstOp2, and FirstOp3 are done in OpenMP}
ELSE
FirstOp1
FirstOp2
FirstOp3
END
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
CloseMP
End3
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
{FirstOp3 is done in OpenMP}
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2
NewToolOp3
NewToolOp4
OpenMP
{NewToolOp5 done in OpenMP}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
CloseMP
End2
End3
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
{FirstOp3a is done in OpenMP}
OpenMP
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
{NewToolOp5a is done in OpenMP}
OpenMP
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
CloseMP
End1
End2
End3
RETURN
NoMPs: {no multiple parts}
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
End3
RETURN
{Start of executable Prog, top level ****************************}
ProgStart {setup and initializations}
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
Wyszukiwarka
Podobne podstrony:
Cin Acr 850SX Sabre PM689 17 3Cin Acr 850SX [WI] M700 87mCin Acr 850SX [WI] M700 87Cin Acr 850SX [D&H] CY84 15Cin Acr 850SX Lancer PM688 17 3Cin Acr 850SX [WI] M598 89Cin Acr 850SX Sab HMT M856 10 1Cin Acr 850SX [LBS] MU11 87Cin Acr 850SX [D&H] C966 12 5więcej podobnych podstron