{5/12/89
Copied & modified; Fanuc 3000C M013.53, for Grand Valley.
Machine is a Hitachi Seiki 60" Horizantal with Fanuc 3000C control.
Change G43 G46 for OfstOn.
Change G28 to G46 for OfstOff and literal 'Z400000' with tool offset.
Move tool change to same line as tool call. Add PreTool.
If OptionalStops, SameTool like NewTool exept for tool change.
Add SetHome to beginnig of prog if ToolChangeAtHome.
Change Home at end of prog to FirstHome. Delete RunTimeComments.
Jim Radcliffe}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{1/16/91, Updated "Fanuc 3000C HS M197.56" to ".76.1", JR}
{1/16/91
Copied & modified: Fanuc 3000C HS M197.76.1
For: Norco
Added to program start block.
Added G45 origin blocks.
Move Speed & tool change to StrtPos line.
Delete PreTool.
Move coolant to OfstOn Line.
OfstOn in Incremental.
Preset ZCP1 after OfstOn, move SpinOn to this line.
Change OfstOn code to G45.
Add AbsOrInc to ZCP2 in line milling & DrillCP line in drilling.
Delete saftey start G code block from NewTool.
Add M19.
Jim Radcliffe}
{9/10/91, Updated Fanuc 3000C HS [NI] M384.76.1 to .80 format, JR}
{9/10/91
Copied & modified: Fanuc 3000C HS [NI] M384.80
For: Bizal Mfg
Machine: Acraloc
Control: Fanuc 3000C
Added Z to preset line at beginning of program.
Deleted ToolChng, only needs OpToolID to do tool change.
Spindle:
changed SpinOn code from M03 & M04 to S03 & S04
moved SpinOn to StrtPos line.
deleted Speed, speeds are set manually.
deleted 'M19' spindle lock
deleted SpinOff
Length Offsets:
deleted IncValue from OfstOn line.
deleted 'Z-0' from OfstOn, using ZCP1
deleted Preset line following OfstOn
deleted IncValue from OfstOff line.
changed 'Z-0' to 'Z30000' on OfstOff line
changed OfstOff code from G46 to G45
Deleted CoolOn & CoolOff commands.
Deleted OptionalStops section from SameTool
Changed to No Nested Sub output format
Put tool# 12 in spindle at end of program.
Jim Radcliffe}
#1 = '#.00'
#2 = '###^##0'
#3 = '*###^##0'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^###;'
#7 = '###^###0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(CRCNormalVectorX#,7)
FORMAT(CRCNormalVectorY#,7)
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
PSInit: {reset flags}
RotateF
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab {drop unconditional for proper tagging}
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqLabC 'M98Pł' Tag# 'R' Repeats# EOL
StartSub
RETURN
FinishSub1: {part 1}
UnSkipZ
IF FeedConnect?
SeqLabC CRCOffC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
END
RETURN
FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN
OpenMP:
IF EquallySpacedOffsets?
TagInc
SeqLabC 'M98Pł' Tag# 'R' Parts# EOL
StartSub
END
RETURN
CloseMP:
IF EquallySpacedOffsets?
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
FeedC MoveXYZC FeedRateC EOL
ELSE {need vectors}
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
DecelMove2
END
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
FeedC MoveXYZC DecelFeed EOL
ELSE {need vectors}
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst DecelFeed EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
FeedC MoveXYZC FeedRateC EOL
ELSE {CRC needed and not yet activated, need vectors & offset}
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
END
END
RETURN
ToolPath2: {NoNesting} {.72.1, this is for AutoCycles only}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqLabC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
NEXTFeat
RETURN
CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqLabC IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqLabC RapidC PRIME ZCP2 EOL
END
NextRep
SeqLabC AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN
ToolPath:
EACHFeat
IF PointFeat?
SeqLabC MoveSXYC EOL
IF AutoCycle?
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
SeqLabC 'M98Pł' Tag# EOL
ELSE
CutAutoCycle
END
ELSE
SeqLabC 'M98Pł' Tag# EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLabC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect? {.72.1, minor changes to entry}
SeqLabC FeedC StrtPosC EOL
SeqLabC ZInC FeedEntC EOL
ELSE
SeqLabC RapidC StrtPosC EOL
SeqLabC ZCP2C EOL
IF FeedEntry?
SeqLabC FeedC ZInC FeedEntC EOL
ELSE
SeqLabC RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
END
NextRep
ELSE
TagInc
StdSub
Milling
FinishSub1
FinishSubG92
END
RETURN
ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
TagInc
AutoCycPat {write pattern moves and main calls}
StartSub
SaveSubStatus {save tool position}
SetSRXYtoSP
SeqLabC IncValue EOL
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
SeqLabC ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqLabC RapidC PRIME ZCP2 EOL
END
NextRep
SeqLabC AbsOrInc RapidC ZCP2 EOL
SetSRSubXY {restore tool position}
SetSRSubMove
SeqLabC EndSub EOL
CloseSub
END
RETURN
ZonlyRep:
TagInc
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
IF MultipleParts? {NoNesting}
SkipZ
ToolPath
FinishSub1
ELSE
SeqLabC 'M98Pł' Tag# EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
StartSub
SkipZ
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
END
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
SeqLabC Plane DrillOff CRCOff 'G98' IncValue Rapid EOL
SeqLabC 'G45X-0H30' EOL
SeqLabC 'G45Y-0H31' EOL
SeqLabC Preset 'X0Y0Z30000' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
CheckPass
SeqLab AbsOrInc Rapid StrtPos OpToolID SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC StrtPos EOL
END
SeqLabC OfstOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC OfstOff 'Z30000' LastToolOffset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation}
DoOpComments
DoPostScript
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos OpToolID SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC StrtPos EOL
END
SeqLabC OfstOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC OfstOff 'Z30000' LastToolOffset EOL
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
SeqLabC 'M00' EOL
{Start new Operation}
GetStartOfSameTool
SeqLabC Plane AbsOrInc Rapid StrtPos SpinOn EOL
SeqLabC OfstOn EOL
ELSE
IF NewToolOffset?
SeqLabC OfstOff 'Z30000' LastToolOffset EOL
{Start new Operation}
GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqLabC OfstOn EOL
ELSE
{Start new Operation}
GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
ELSE
IF Drilling?
SeqLabC AbsOrInc DrillCP EOL
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
ToolPath
SeqLabC DrillOff EOL
IF Repeats?
FinishSubG92
END
SeqLabC RapidC ZCP3C EOL
END
END
NextOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC OfstOff 'Z30000' ToolOfst EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC 'T12' EOL
SeqLabC 'M30' EOL
EOR EOL
nullfoot EOL
EOR EOL
Post
EOR EOL
Close
Retag
IF UseComments?
Reopen
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 3000C Mat [BM] M482 80Fanuc 10M Okada [BM] M467 80Fanuc 6M Mat [BM] M481 80Fanuc 3000C Acr [FEL] M677 79 1Fanuc 6M Acr MX15 M100 80Fanuc 3000C Acr (BK) M478 81Yasnac MX1 Acr [BM] M483 80Fanuc 11M Acr M15L M173 80Fanuc 3000C HS M197 80Fanuc 11M MS [HM] M433 80Fanuc 3000C HS [NI] M384 89Fanuc 11M MS [BTD] M432 80 1Fanuc 3000C HS [NI] D384 13Cin 10VC Acr 900MC M245 80 2mFanuc 3000C Mat LH PM M495 89 3Fanuc 3000C (AAR) M351 79więcej podobnych podstron