{Change Comments ***********************************************************}
{5/28/92
Copied & modified: Fanuc 0T/3T Miyano L008.82.1
For: Waltz Brothers, Inc. (708) 520-1122
Control: Fanuc 0T Model C
Machine: Miyano BNC-S
Created new ncPost Processor per notes, control manual & samples supplied by Alfrado.
Machine is a single turret dual spindle lathe.
Tools 1 thru 16 operate on the main spindle, tools 17 thru 32 operate on the sub spindle.
Tool 1 is always a Bar Feed Stop and Tool 6 is always a cutoff tool.
The sub spindle may move on an axis B to to get the part from the main spindle.
The first operation is always a Bar Feed operation.
JR}
{4/15/93
Modified: Fanuc 0T Miy BNC-S [WB] L260.82
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
DWB}
{7/28/94
Copied & modified: Fan 0T Miy BNC-S [WB] L260.82.1
For: Braden Eng / Waltz Bros
Control: Fanuc 0T
Machine: Miyano BND 34
Added M213, G110G0B0
Modified BarFeed to call Tool, Offset and Spindle encoder on 1st line.
Changed Sub Spindle tool flag to tools over 10.
Moved CheckEncoder to OpToolID line, tools 1 - 10 = M91; tools over 10 = M191
Changed SpinOn to output M93/M94
Changed CoolOn to output M28.
Modified end of program
Added ErrorDetection.
Tool#6 is allways cut off tool, added special coding.
Jim Radcliffe}
{8/31/94
Modified: Fanuc 0T Miy BND-34 Lxxx.82.1
For: Braden Eng / Waltz Bros
Changed descrimination for sub spindle from tools over 10 to tools over 16.
Moved M18 to line after 'G04U.5' in BarFeed sub.
Added 'G110T70' to CutOffStuff sub.
Added 'G110G1B0F.010' to CutOffStuff sub.
Jim Radcliffe}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(ZStockMin#,2)
FORMAT(ZStockMax#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FinishXDia#,2)
FORMAT(Taper#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
{Prog Subroutines **********************************************************}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN
FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN
ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN
FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN
GetZCPC:
IF ToolOver?('16') {tools over 16 are used on sub spindle}
'Z' TrackZ# ZStockMin#
ELSE
ZCPC
END
RETURN
AppMove:
StockOff
IF ToolOver?('16') {tools over 16 are used on sub spindle}
'Z' TrackZ# ZStockMin#
ELSE
ZCP
END
CoolOn
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN
CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN
BarFeed:
IF UseComments?
IF OperationIDComment?
'( OPERATION 0: BarFeed )' EOL
END
IF OperationComment?
'( Bar Feed )' EOL
END
IF ToolTypeComment?
'( TOOL 1: Bar Feed Stop )' EOL
END
IF ToolComment?
'( Bar Feed Stop )' EOL
END
END
SeqLabC 'T0101' 'M91' EOL
SeqLabC Rapid 'X0' EOL
SeqLabC 'Z' ZStockMin# EOL
SeqLabC ProgStop EOL
SeqLabC 'M17' EOL {open Main chuck}
SeqLabC Rapid 'Z' ZStockMax# EOL
SeqLabC 'G04U.5' EOL
SeqLabC 'M18' EOL {close Main chuck}
SeqLabC Rapid 'Z' ZStockMax# EOL
SeqLabC 'G30W0' EOL
SeqLabC 'G30U0' EOL
SeqLabC ProgStop EOL
RETURN
CheckSpinOn:
IF ToolOver?('16') {tools over 16 are used on sub spindle}
IF CWSpindle?
'M104'
ELSE
'M103'
END
ELSE
IF Equal? Tool# Num#('6')
'M203' { Start both spindles for cut off }
ELSE
SpinOn
END
END
RETURN
CheckEncoder:
IF ToolOver?('16') {tools over 16 are used on sub spindle}
'M191'
ELSE
'M91'
END
RETURN
ErrorDetection:
IF ToolOver?('16') {tools over 16 are used on sub spindle}
'M52'
END
RETURN
CutOffStuff:
SeqLabC 'G28U0' EOL
SeqLabC 'M117' EOL { Open Sub Collet }
SeqLabC ZCP SpinOff EOL { Move tool to Clearance }
SeqLabC 'G110T70' EOL
SeqLabC 'G110G0B0' EOL { Move sub spindle onto part }
SeqLabC 'G110G1B0F.010' EOL
SeqLabC 'M118' EOL { Close Sub Collet }
SetLineStrtChr('/')
SeqLabC 'M17' EOL { Open main spindle collet }
SetLineStrtChr('')
SeqLabC 'G110G0B0' EOL { Move bar out to cutting length }
SeqLabC 'M18' EOL { Close main spindle collet }
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
SeqLabC 'G20G99G40' EOL
SeqLabC 'G30U0' EOL
SeqLabC 'G30W0' EOL
SeqLabC 'M213' EOL { Part Conveyor On }
SeqLabC 'G110G0B0' EOL { send sub spindle home }
BarFeed
DoOpComments
DoPostScript
Plane
SeqLabC OpToolID LatheOffset CheckEncoder EOL
SeqLabC ErrorDetection EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
IF Equal? Tool# Num#('6')
CutOffStuff
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
CheckSpinOn EOL
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
IF Equal? LAST Tool# Num#('6')
SeqLabC 'M272' EOL { Cut Off confirmation on }
SeqLabC 'M273' EOL { Cut Off confirmation off }
SeqLabC 'G110G0B0' EOL
END
IF LAST ToolOver?('16') {tools over 16 are used on sub spindle}
SeqLabC 'Z' ZStockMin# EOL
ELSE
SeqLabC ZCPC EOL
END
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC 'G30U0W0' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
{Start new Operation}
DoOpComments
DoPostScript
SeqLabC OpToolID LatheOffset CheckEncoder EOL
SeqLabC ErrorDetection EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
IF Equal? Tool# Num#('6')
CutOffStuff
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
CheckSpinOn EOL
Approach
ELSE
IF SameTool? {.62}
{Start new Operation}
StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC GetZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC GetZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC GetZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ToolAngle EOL
IF AutoFinish?
IF Taper?
SeqLabC Rapid
'X' ADD# FinishXDia# MUL# Taper# NumSc#('2') { Outputs start of Taper }
EOL
SeqLabC 'G32' XatFinZ FinZ ThrdLead EOL
ELSE
SeqLabC Rapid XatFinZ EOL
SeqLabC 'G32' FinZ ThrdLead EOL
END
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC GetZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC 'G30U0M213' EOL
SeqLabC 'G30W0' EOL
SeqLabC 'G110G0B0' EOL { send sub spindle home }
SeqLabC 'M35' EOL { Parts Catcher forward }
SeqLabC 'M105' EOL { Sub Stop }
SeqLabC 'M117' EOL { Sub Collet Open }
SeqLabC 'M36' EOL { Parts Catcher Backward }
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 0T SL 25 [CS] L323 82 1Fanuc 0T Miy BNC T L091 85Fanuc 0T Miy BNC 34T L312 85Fanuc 0T 3T Miy [SP] L242 82 2Fanuc 0T (Anzon1) L077 82 1mFanuc 0T Miyano [A&B] L247 82 6Fanuc 0T Nakamora L248 82Fanuc 0T Yam CK1A L336 82 1Fanuc 0T Azuma MSI L245 82 2Fanuc 0T [RWMT] L369 82 2Fanuc 0T Ikegai [TSS] L348 82 3Fanuc 0T 3T Miy [GNR] L344 85Fanuc 0T Miyano [TPM] L329 82 3Fanuc 0T Okuma [VT] L255 82więcej podobnych podstron