{Change Comments ***********************************************************}
{12/19/88
In the 1st op, PreTool only IF NOT LastTool? and at end of
program, UnTool & ToolChng only IF ToolOver?(1).
This is for when only 1 tool is used to eliminate calling
up and changing the tool that is already in the spindle
Jim Radcliffe}
{2/7/90, Updated to Version 3.2 per Fanuc 6M M001.70 Format, DWB}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{4/02/91
Modified: Fanuc 11M MS M020.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Kim Michelman}
{06/25/91
Modified: Fanuc 11M MS M020.79
For: Barbee Tool & Die
Took out all 'G92' (Preset), replaced with incremental repeats
per Yasnac MX3 Mat 800 M243.79 Format.
Unconditional 'X0' & 'Y0' @ every New Tool.
Replaced (Seq) with ('N' Tool# '00')
Kim Michelman}
{08/08/91
Modified: Fanuc 11M MS [BTD] M432.80
For: Barbee Tool & Die
Fixed 'G28' and 'G43' problem.
Added Rapid IncValue to OffstOff.
Added 'G28Y0' after OffstOff.
Changed 'G' and 'M' formats to force leading zeros.
Kim Michelman}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '##.####;'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
{Prog Subroutines **********************************************************}
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
PSInit: {reset flags}
NewWFOF
RotateF
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO
StartSub
SeqC StrtPos EOL
ELSE
EachPart
IF FirstPart? AND OneToolAllParts?
IF FullUp?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid ZCP2C EOL
END
SetStatusOff
ELSE
SeqC Rapid StrtPos EOL
END
SeqC SubCall CallLab EOL
NextPart
SetStatusOn
StartSub
END
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC AbsOrInc EndSub EOL
CloseSub
END
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN
ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
IF AutoCycle?
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN
WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'G' NewWFO#
IF FirstOperation?
IF NOT LastTool?
PreTool
END
Plane
ELSE
PreTool
END
EOL
END
ELSE
SeqC
IF NeedWFO1?
'G' NewWFO#
END
IF FirstOperation?
IF NOT LastTool?
PreTool
END
Plane
ELSE
PreTool
END
EOL
END
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
IncValue
RETURN
AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
StdRep:
EachRep
IF FirstCycle?
IF AnyZShift?
FindAnyZMoves
IF NOT NoZMoves?
SubWarning
END
IF FeedConnect?
SeqC FeedC ZIn FeedEnt EOL
ELSE
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
END
END
SeqC SubCall CallLab EOL
StartSub
IncValue
IF NOT FeedConnect? AND NOT AnyZShift?
EntryMove
END
ToolPath
IF FeedConnect?
SeqC CRCOffC EOL
IF NOT MultipleParts?
AbsOrInc
END
ELSE
SeqC CRCOffC RapidC AbsOrInc ZCP2C EOL
IF MultipleParts?
IncValue
END
END
SeqC EndSub EOL
SaveSubStatus
CloseSub
ELSE
IF FeedConnect?
SeqC Feed StrtPos EOL
ELSE
SeqC Rapid StrtPos EOL
END
IF AnyZShift?
IF FeedConnect?
SeqC FeedC ZIn FeedEnt EOL
ELSE
IF FeedEntry?
IF ZshiftOnly?
SeqC RapidC ZCP2C EOL {rapid deeper each cycle}
END
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
END
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
IF FeedConnect?
SetSRSubZRC
ELSE
SetSRSubZ {because of G90 Z.1}
END
END
NextRep
SetSRSubMove
RETURN
XYOnlyRepAutoCycle:
EachRep
EACHFeat
IF FirstCycle? AND FirstFeat?
ELSE
SeqC RapidC MoveSXYC EOL
END
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
NEXTFeat
NextRep
AutoCycCutSub1
EntryMove
AutoCycCutSub2
RETURN
ZOnlyRepAutoCycle:
EachFeat
SeqC MoveSXYC EOL
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SetPass1 {element cut moves}
EachRep
IF FeedConnect?
SeqC Feed ZIn FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC ZCP2 EOL
END
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC ZIn EOL
END
END
SeqC SubCall CallLab EOL
IF FirstCycle?
SaveSubStatus {save tool position}
END
NextRep
IF FeedConnect?
SeqC RapidC ZCP2 EOL
END
ReSetPass2 {restore for positioning moves}
NextFeat
SetSRSubMove
SetSRSubZ {restore SR to 1st position value}
AutoCycCutSub1
IF NOT FeedConnect?
SetStatusRapid
END
AutoCycCutSub2
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN
Drill:
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
ToolPath
SeqC 'G80' EOL
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' Use after ENDOP in previous OP for a same tool WFO change' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
'N' Tool# '00' Rapid CRCOff 'G80' Plane 'X0''Y0' EOL
DoPostScript
WFOStuff
DoOpComments
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC Rapid IncValue OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC Rapid IncValue 'G28Y0' EOL
SeqC AbsOrInc EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL {top level, need ABS OR INC}
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
{Start new Operation}
SeqC ToolChng EOL
SeqC OpToolID EOL
DoOpComments
'N' Tool# '00' Rapid CRCOff 'G80' Plane 'X0''Y0' EOL
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC Rapid IncValue OfstOff EOL
SeqC AbsOrInc EOL
SeqC 'M00' EOL
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid IncValue OfstOff EOL
SeqC AbsOrInc EOL
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
{Start new Operation}
GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF AutoCycle?
IF ZshiftOnly?
ZOnlyRepAutoCycle
ELSE {not Z only}
XYOnlyRepAutoCycle
SeqC RapidC ZCP3C EOL
END
ELSE {not AutoCycle}
StdRep
SeqC RapidC CRCOffC ZCP3C EOL
END {end Auto Cycle IF}
ELSE {no repeat OPs}
Milling
SeqC RapidC CRCOffC ZCP3C EOL
END
ELSE
IF Drilling?
SeqC DrillCP EOL
IF Repeats?
EachRep
IF FirstCycle?
NewProg
SeqC SubCall CallLab EOL
StartSub
IncValue
Drill
SeqC
IF NOT MultipleParts?
AbsOrInc
END
EndSub EOL
CloseSub
SaveSubStatus
ELSE
SeqC StrtPos EOL
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
SeqC RapidC ZCP2C EOL
ELSE
Drill
SeqC RapidC ZCP3C EOL
END
END
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC Rapid IncValue OfstOff EOL
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC Rapid IncValue 'G28Y0' EOL
SeqC AbsOrInc EOL
IF ToolChangeAtHome?
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
IF ToolOver?(1)
SeqC UnTool EOL
SeqC ToolChng EOL
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
Fanuc 11M MS [HM] M433 80Fanuc 11M MS [RE] M734 89 1Fanuc 11M MS [EE] NMT57 16 2Fanuc 11M MS [EE] NMT57 16 2mFanuc 6T MS [ BTD] L221 82Fanuc 11M Mazak Laser M454 80Fanuc 11M MS C020 12Fanuc 11M MS PM020 17 3Fanuc 11M MS M020 89mFanuc 11M Acr M15L M173 80Fanuc 11M (JP) M313 80 1Fanuc 10T MS [2 G54] L066 82Fanuc 11M [TM] CQ07 16 2Fanuc 6T MS [SE] L683 85więcej podobnych podstron