{ 8/31/88 }
{ updated Bandit IIA M006.53 for N.C. Engineering }
{ go to ZCP1C before OfstOff }
{ minor change to begin & end every program }
{ Z negative value for peck }
{ use G89 routine if drilling and retract to ZCP1 }
{ deleted preset toolchange positions between tools }
{ Jim Radcliffe }
{12/2/88
General change to all Bandits.
Deleted: CRCOnC & CRCOffsetC commands from 6 places in ToolPath.
Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
Jim Radcliffe}
{6/20/89
Modified; Bandit IIA Shiz (NCE) M153.57.
Change "AbsValue" in first operation to "AbsOrInc".
Jim Radcliffe}
{10/12/89
Modified: Bandit IIA Shiz (NCE) M153.58
For: N.C. Enginerring
Changed "/Z" to "Z" in Drilling format Bore (G82).
Jim Radcliffe}
{1/10/90, Updated: Bandit IIA Shiz (NCE) M153.59, to .69 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{2/14/91, Updated Bandit IIA Shiz (NCE) M153.70 to .76.1 format.
Changed "/Z" to "Z" in Drilling format Tap (G84).
Corrected Dwell format.
Feedrate must be on line by itself, all conditions corrected.
Modified Operation Comments, put Tool Comments and suppress if SameTool.
A G code must be the last entry on a line, all conditions corrected.
NOTE: cannot do helical interpolation on this machine
NOTE: The first clearance plane for all non-SameTool operations must be the same for the Tool Offsets to Work properly.
NOTE: The commands Feed & Rapid have no output.
NOTE: The literal N001 at the beginning of the program is for loading program into control.
NOTE: Must call MarkSub for each time the sub will be called to get proper call commands.
NOTE: ***BUG***
The Renum Command when resequncing due to sub output:
* Removes the empty line at beginning of program
* Counts the literal N001 at the beginning of the program as a command.
* Calls incorrect sub numbers in nested sub output.
* Counts Comments as commands.
* Gives all N's a number, including inside comments & the literal N001.
Jim Radcliffe}
{7/1/91, Updated Bandit IIA Shiz (NCE) M153.76.1 to .80 format, JR}
{3/5/91
Modified: Bandit IIA Shiz (NCE) M153.80
Deleted the literal CR & N001 from the beginning of the output.
NOTE these will have to edited in.
Added ZCP2 to G92 sub,
NOTE this should be fixed in all processors as the ZCP2 is not output to the sub.
Jim Radcliffe}
{3/5/91
Copied & modified: Bandit IIA Shiz (NCE) M153.80.1
Machine: Bandit: manual tool change & auto RPM
Changed AutoTool to 'M6'
Deleted the untool sequence from end of program
Jim Radcliffe}
{6/30/93
Modified: Bandit iiM Shiz .80.1
Changed EntryMove sub to use FeedEntC output for SameTool
Jim Radcliffe}
{9/3/93
Modified: Bandit IIM Shiz .80.2
Changed ZDepth to ZDepth# in Drilling,
This processor uses incremental drill depths,
ZDepth outputs from ZCP1 when RetractToCP1 is selected,
ZDepth# works OK
Updated to .81.2 format.
Jim Radcliffe}
{9/15/93
Copied & modified: Bandit IIM Shiz (NCE) M262.81.2
For: MD Research
Created NoSubs version per Fanuc 6M NoSubs M001.81.2
Using Program# for 1st program storage command.
Preset ZCP1 with Home position at beginning of each tool.
Deleted SpeedB, this is a manual Tool Change and manual RPM processor.
Moved OfstOn to before StrtPos.
Modified to use G29 command instead of G89 command for Drilling Retract to 1st CP.
Skip StrtPos at beginning of Drilling operation.
Jim Radcliffe}
{9/20/93, .81.3, metric version, EOP outputs M6, JR}
{9/30/93, .81.4, arc center labels IJK not /I/J/K. Peck Retract label /Z & Z-. JR}
{12/23/93
Modified: Bandit IIM MDR NoS M595.81.4m
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost 4.21.19
Changes made per EMails with Maurizio of Cigraph PTY.
Changed INCHES to MILLIMETERS in ProgramComments.
Changed SetMaxFeed argument from 500 to 999 at setup and initialization.
Changed literal 'G70' [inch] to 'G71' [metric] at FirstOperation.
Added CoolOn on block following SpinOn at FirstOperation, NewTool and SameTool.
Added CoolOff on block following SpinOff at NewTool, SameTool and FinishLastOp sub.
Deleted IF LAST ProgStop? at NewTool as 'M6' is already being forced out.
Changed literal 'M0' to 'M6 for ProgStop at SameTool and FinishLastOp sub'.
DWB}
{1/6/94
Modified: Bandit IIM MDR NoS M595.81.5m
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost 4.21.19
Changes made per EMails with Maurizio of Cigraph PTY.
Moved OfstOnB block to before Home block at FirstOperation, NewTool and SameTool.
Moved OfstOff block to follow Home block at NewTool, SameTool and end of Prog.
DWB}
{1/18/94
Modified: Bandit IIM MDR NoS M595.81.6m
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.2/Compost 4.21.19
Changes made per EMails with Maurizio of Cigraph PTY.
Added Program2# to Format#8.
Added SaveProgNum2 to setup and initializations.
Added 'N' Program2# EOL at FinishLastOp.
This is final block of program and acts like M30 (EOP), rewind to 1st program storage command
noted in Developers comments of 9/15/93.
DWB}
{Prog Numeric Format Definitions *******************************************}
#1 = '0.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '##.##;0.'
#7 = '#;'
#8 = '000'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ZDepth#,4)
FORMAT(Retract#,4)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(Program#,8)
FORMAT(Program2#,8)
{Prog Subroutines **********************************************************}
RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit: {reset flags}
RotateF
RETURN
PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN
DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN
ExitFeed:
IF FIFO?
FeedEntC
END
RETURN
FormatArc:
IF XMove? AND YMove?
IF ArcCW?
CWArcC {no output}
ELSE
CCWArcC {no output}
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
ELSE
Feed MoveXYZC
END
RETURN
StdRapid:
IF XMove? OR YMove? OR ZMove?
Rapid MoveXYZC EOL
END
RETURN
StdLine:
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedRateC EOL
Feed MoveXYZC EOL
DecelMove2
END
DecelFeed EOL
Feed MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
FeedRateC EOL
Feed MoveXYZC EOL
END
END
RETURN
StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
ArcFeedC EOL
FormatArc EOL
DecelMove2
END
DecelFeed EOL
FormatArc EOL
ELSE
ArcFeedC EOL
FormatArc EOL
END
NEXTQuadrant
RETURN
ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN
EntryMove:
IF FeedEntry?
IF SameTool?
FeedEntC EOL
ELSE
FeedEnt EOL
END
Feed ZInC EOL
ELSE
Rapid ZInC EOL
END
RETURN
CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO?
FeedEntC EOL
FeedC PRIME ZCP2 EOL
ELSE
RapidC PRIME ZCP2 EOL
END
END
NextRep
ELSE
EntryMove
ToolPath2
END
IF FIFO?
AbsOrInc EOL
FeedEntC EOL
FeedC ZCP2 EOL
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN
ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
IF NOT FirstFeat?
MoveSXYC EOL
IF RetractToCP1?
Rapid ZCP2 EOL
'G29' EOL {execute drill cycle}
Rapid ZCP1 EOL
END
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN
GetStrtPos:
IF NOT Drilling?
StrtPos
END
RETURN
DrillCycle:
GetCycle
FeedEnt EOL
IF Peck?
'/'
END
'Z' ZDepth# Dwell Peck
IF Peck?
IF PeckChipBreaker?
'/Z'
ELSE
'Z-'
END
Retract#
END
Cycle EOL
RETURN
DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
ZCP1C EOL
OfstOff EOL
END
DoOpComments
ELSE
DoOpComments
DoPostScript
Plane {no output}
SpinOn EOL
CoolOn EOL
AbsOrInc EOL
OfstOnB EOL
Feed Home ZCP1 Preset EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
Rapid GetStrtPos EOL
ELSE
Rapid GetStrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
ZCP1C EOL
DoEndOpPS
SpinOff EOL
CoolOff EOL
IF ToolChangeAtHome?
Rapid Home EOL
END
OfstOff EOL
'M6' EOL { ProgStop }
END
{Start new Operation}
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
ZCP1C EOL
OfstOff EOL
END
DoOpComments
ELSE
DoOpComments
DoPostScript
Plane {no output}
SpinOn EOL
CoolOn EOL
AbsOrInc EOL
OfstOnB EOL
Feed Home ZCP1 Preset EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
Rapid GetStrtPos EOL
ELSE
Rapid GetStrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
ZCP1C EOL
SpinOff EOL
CoolOff EOL
Rapid Home EOL
OfstOff EOL
'M6' EOL { ProgStop }
{Start new Operation}
GetStartOfSameTool
Plane {no output}
SpinOn EOL
CoolOn EOL
OfstOnB EOL
Feed Home ZCP1 Preset EOL
Rapid GetStrtPos EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
CoolOff EOL
END
GetStartOfSameTool
PlaneC EOL
Rapid GetStrtPos EOL
IF NOT CoolOff? AND LAST CoolOff?
CoolOn EOL
END
END
END
END
END
{ Common Point for All Operations }
RapidF# {forces the output of a conditional feedrate for each operation}
IF Milling?
Rapid ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
Connect StrtPos EOL
IF NOT FeedConnect?
ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
ExitFeed EOL
IF NOT FeedConnect?
ExitType PRIME ZCP3C EOL
END
NEXTRep
END
END
IF AutoCycle?
ZCP3C EOL
ELSE
ExitFeed EOL
ExitType ZCP3C EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
IF RetractToCP1?
DrillCycle
DrillOff EOL
Rapid StrtPos EOL
Rapid ZCP2 EOL
'G29' EOL {execute drill cycle}
Rapid ZCP1 EOL
ELSE
StrtPos EOL
Rapid ZCP2C EOL
DrillCycle
StrtPos EOL
END
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
DrillOff EOL
END
Rapid ZCP3C EOL
IF Repeats?
NEXTRep
END
Rapid ZCP3C EOL
END
END
RETURN
FinishLastOp:
ZCP1C EOL
DoEndOpPS
SpinOff EOL
CoolOff EOL
IF FIRST ToolChangeAtHome?
Rapid FirstHome EOL
END
OfstOff EOL
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
'M6' EOL { ProgStop }
END
ELSE
EOP EOL
END
'N' Program2# EOL
RETURN
DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN
NextTools1stOp:
SetNextToolOp Operation#
RETURN
GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN
DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3800')
SetMaxFeed('999')
SaveProgNum2
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
RestoreScale
ASCII('13')
'N' Program# '&' 'G71' EOL
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
Post
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum
Wyszukiwarka
Podobne podstrony:
Bandit IIM Shiz (NCE) M262 81 2Bandit IIIA Kas [AP] M375 81 2Bandit II [MDR] L231 82 4mBandit IIM (No Z) M225 79Bandit IIIM SMax M024 81Fanuc 10M (AGA) M147 81 2CE PC NosBandit IV AB [DM] MV32 89 1Tosnuc 600M VMC 45 M442 81 3DM 81 Diper KenwoodaBP IIA (HAC) M200 81Fagor 8050 [MDR] MX28 89mSDIZO MDRwięcej podobnych podstron