{Change Comments ***********************************************************}
{8/16/93
Copied & modified: Fanuc 6M M001.81.2
For: Olson Manufacturing & Distribution, Inc.
Control: Centurion V
Machine: Milltronics Partner 1
Created new processor from FastCAM II manual (same info as Centurion V manual!).
Added 'G20', Inch Program, to Saftey Start Block.
Added 'G32', for a Z move to Tool Change position, to Saftey Start Block.
CRCOff on last non-arc feat.
OfstOn, G43 H value, is applied to the axis perpendicular to the current plane.
Call literal G17 before OfstOn and added sub GetPlane, Plane has not output.
OfstOff outputs G49Z0.
Modifications for support and enhancement Drilling section.
Jim Radcliffe}
{8/19/93, .81.3, corrected an ELSE/END bug in ToolPath, JR}
{8/27/93, .81.4, no Home, machine home at end of program, 4 place O codes, JR}
{12/22/94
Updated: Centurion V M589.81.4
For: Gibbs & Associates/Texas Precision Manufacturing
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.22C/Catalyst v2.14.22PPC/Compost 4.21.23
Changes made per Pete Jackson.
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Changed TrackZNO# ZDepth# to TrackZNO# FIRST SPZ# at IF Drilling.
SPZ# is affected by SetScale, whereas ZDepth# is not.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to output CRCOnC in OneFeat ToolPath.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 at all ZMoveOnly Feature Retract blocks.
DWB}
{12/22/94
Copied: Centurion V M589.81.5
Created: Centurion V [TPM] M726.81.2
For: Texas Precision Manufacturing
Machine:
Control:
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.22C/Catalyst v2.14.22PPC/Compost 4.21.23
Changes made per Pete Jackson.
Customer reported incorrect format of subprogram calls.
Changed all occurances of SubCall CallLab to literal 'GOSUB' Program#.
Changed all occurances of EndSub to literal 'RETURN'.
DWB}
{4/20/95
Updated: Centurion V [TPM] M726.81.2
For: Texas Precision Manufacturing
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Changes made per Jonathan McCann of Texas Precision Manufacturing
Updated to Version 4.3 per Fanuc 6M [V] M001.10a Format.
Moved CRCOffset from StdLine sub to CkCRC sub.
Moved CoolOn to StartPos block at FirstOp3, NewToolOp5 and SameToolOp3 subs.
Moved AbsOrInc to OfstOn block at FirstOp3, NewToolOp5 and SameToolOp3 subs.
Moved OfstOn block to before StrtPos block at FirstOp3, NewToolOp5 and SameToolOp3 subs.
Changed OfstOn to 'G43' ToolOfst ZCP1 at FirstOp3, FirstOp3a, NewToolOp5, NewToolOp5a and
SameToolOp3 subs.
Added ToolChangeAtHome at NewToolOp2 sub.
Added FIRST ToolChangeAtHome at End2 sub.
DWB}
{5/16/95
Modified: Centurion V [TPM] M726.10
For: Texas Precision Manufacturing
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Changes made per Jonathan McCann of Texas Precision Manufacturing
Moved Rapid from StrtPos block to 'G43' block at FirstOp3, NewToolOp5 and SameToolOp3 (2x).
DWB}
{5/24/95
Modified: Centurion V [TPM] M726.10.01
For: Texas Precision Manufacturing
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Changes made per Jonathan McCann of Texas Precision Manufacturing
Added support for Rigid Tap Cycle.
G88, P.3 Dwell and F Pitch Value.
DWB}
{Prog Numeric Format Definitions ****}
#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.##'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(DIV#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Retract#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
{Prog Subroutines ****}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN
PSInit:
NewWFOF
RotateF
MasterOpF
CallMasterOpF
RETURN
PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC 'GOSUB' Program# RepLab RepCycs EOL { SubCall CallLab }
StartSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC 'RETURN' EOL { EndSub }
CloseSub
SeqC Preset UnshftRC EOL
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC SetWFO EOL
SeqC 'GOSUB' Program# RepLab OnePart EOL { SubCall CallLab }
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC 'GOSUB' Program# RepLab Parts EOL { SubCall CallLab }
END
StartSub
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC 'RETURN' EOL { EndSub }
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC 'RETURN' EOL { EndSub }
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN
RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
CkCRC: { 4.2 }
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
CRCOnC
IF NOT EmptyLine?
ResetCRCNum
END
CRCOffsetC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN
StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN
ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC 'GOSUB' Program# EOL { SubCall CallLab }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF AutoCycle?
SeqC DoAbsOrInc
IF LastFeat?
CRCOffC
END
RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC
END
RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC 'RETURN' EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC Connect AbsOrInc StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {added Rapid, reads better}
{can't call for cycle = 1, changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC 'GOSUB' Program# EOL { SubCall CallLab }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC 'RETURN' EOL { EndSub }
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqC 'GOSUB' Program# EOL { SubCall CallLab }
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC 'RETURN' EOL { EndSub }
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN
SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
GetPlane:
IF XYPlane?
{G17 is allready active}
ELSE
IF XZPlane?
'G18'
ELSE
'G19'
END
END
RETURN
OpGuts:
SeqC Plane GetPlane EOL
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF Tap? AND OptCyc1? { Rigid Tap }
SeqC 'G88' FromCP StrtPos ZDepth RLevel 'P.3' 'F' DIV# DirectTapFeed# SpeedRPM# EOL
{ P.3 = .3 Second Dwell, F = Pitch }
ELSE
SeqC
IF FIFO? AND Dwell?
'G89'
ELSE
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
END
FromCP StrtPos ZDepth RLevel Dwell Peck
IF PeckChipBreaker?
'U' Retract#
END
IF Peck?
'D' Retract#
END
FeedEnt EOL
END
IF CallMasterOp?
SeqC 'GOSUB' CallMasterNum# EOL { SubCall CallLab }
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC 'GOSUB' Program# EOL { SubCall CallLab }
StartSub
ToolPath
SeqC 'RETURN' EOL { EndSub }
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN
NotSameToolWFO:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC 'G' NewWFO# EOL
ELSE
IF NeedWFO1?
SeqC 'G' NewWFO# EOL
END
END
END
RETURN
SameToolWFO:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC 'G' NewWFO# EOL
END
END
RETURN
InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN
FirstOp1:
Seq 'G17' 'G20' 'G32' CRCOff DrillOff EOL
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN
FirstOp2:
SeqC Speed SpinOn EOL
RETURN
FirstOp3:
CheckPass
SeqC Rapid AbsOrInc 'G43' ToolOfst ZCP1 EOL { OfstOn }
SeqC StrtPos CoolOn EOL
RETURN
FirstOp3a: {can't XY position before WFO}
CheckPass
SeqC 'G43' ToolOfst ZCP1 CoolOn EOL { OfstOn }
RETURN
NewToolOp1:
SeqC CoolOff EOL
SeqC OfstOff EOL
RETURN
NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN
NewToolOp3: {Start new Operation}
Seq 'G17' 'G20' 'G32' CRCOff DrillOff EOL
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN
NewToolOp4:
SeqC Speed SpinOn EOL
RETURN
NewToolOp5:
CheckPass
SeqC Rapid AbsOrInc 'G43' ToolOfst ZCP1 EOL { OfstOn }
SeqC StrtPos CoolOn EOL
RETURN
NewToolOp5a:
CheckPass
SeqC 'G43' ToolOfst ZCP1 CoolOn EOL { OfstOn }
RETURN
SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC OfstOff EOL
SeqC SpinOff EOL
SeqC 'M0' EOL
SeqC 'G17' 'G20' CRCOff DrillOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff EOL
SeqC 'G17' 'G20' CRCOff DrillOff EOL
END
END
RETURN
SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN
SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC SpeedC SpinOn EOL
SeqC Rapid AbsOrInc 'G43' ToolOfst ZCP1 EOL { OfstOn }
SeqC StrtPos CoolOn EOL
ELSE
SeqC SpeedC EOL
SeqC Rapid AbsOrInc
IF NewToolOffset?
'G43' ToolOfst ZCP1 EOL { OfstOn }
SeqC
END
StrtPos EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN
End1:
SeqC CoolOff EOL
SeqC OfstOff EOL
RETURN
End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN
End3:
SeqC 'G53' Rapid 'Y0.' EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp
IF FirstOperation?
InitOp
OpenMP
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
CloseMP
End3
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp
IF FirstOperation?
InitOp
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
CloseMP
End2
End3
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp
IF FirstOperation?
InitOp
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
FirstOp3a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
NewToolOp5a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
CloseMP
End1
End2
End3
RETURN
NoMPs: {no multiple parts}
EachOp
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
End3
RETURN
{Start of executable Prog, Top Level ****}
ProgStart {setup and initializations}
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
Wyszukiwarka
Podobne podstrony:
ranking kont bank bankowych 2010 10 02semestr I 10 02 2012rPrzepisownia Szarlotka sypana szybka 2015 10 022013 10 02utk 10 02 0310 0210 02 26 WDB sekw 1Angorka 10 02 21więcej podobnych podstron