{Change Comments ***********************************************************}
{9/24/92
Copied & modified: Fanuc 10M [PP] M451.81.2
For: B&C
Customer documentation was poor, and the new information that was added to the end of the
prog was moved down below the 'M99' command.
KM}
{8/18/93
Modified: Seikos M2 HS [BC] M517.81.3
For: B&C
Changes made per conversations with Rick Parks at B&C
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
Changed Tap Cycle from G84 to G841 in Composts Drill Cycles Dialog.
This is Direct Rigid Tapping.
Added PostScript OptionalCycle1 for G84 Canned Tap Cycle at Drilling.
Modified output of WorkFixtureOffsets for MultipleParts at OpenMP.
Configured to output following values, (read from left to right):
G54 G55 G56 G57 G58 G59
G540 G550 G560 G570 G580 G590
G541 G551 G561 G571 G581 G591
G542 G552 G562 G572 G582 G592
G543 G553 G563 G573 G583 G593
G544 G554 G564 G574 G584 G594
G545 G555 G565 G575 G585 G595
G546 G556 G566 G576 G586 G596
G547 G557 G567 G577 G587 G597
G548 G558 G568 G578 G588 G598
G549 G559 G569 G579 G589 G599
DWB}
{9/28/95, Updated Seikos M2 HS [B&C] M517.81.4 to .85 format per Fanuc 6M M001.85.01.03, JR}
{2/9/96, created B style Advanced Mill Version per Fanuc 6M (FW) B001.10.02, JR}
{2/13/96
Initial: Seikos M2 HS [B&C] B517.10.02
Created: Seikos M3 HS [SKS] Bxxx.10.02
ForUser: SKS Machining
Control: Seikos M3
Machine: Hitachi Seiki VK45 with Yuasa Indexer
Develop: ComPost 4.21.33, Catalyst68K v3.0C
Comment: New Processor per marked up readout from Patrick Smolarek.
Deleted literal 'M0' from beginning of program.
Changed literal 'X0Y0' at beginning of first tools to StrtPos.
Changed SpinOn to GetSpinOn.
Outputs M13 for SpinOn and CoolOn.
Outputs M3 if CoolOn was not specified.
Deleted CoolOn except where needed in SameTool.
Added literal 'M123' at end of tools.
Does a full spindle retract
Turns off the spindle
Turns off the coolant
Changed EOP output from M99 to M30.
Indewxer is commanded by M code 70
Combined CSAngleA & CSAngleB
Jim Radcliffe}
{2/16/96, Updated .10 to .11 version
Fixed taping cycles pre customer
removed M15 & g91 line per customer.
JM}
{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}
{4/3/96,
Initial: Seikos M3 HS [SKS] B932.12
Created: Seikos M3 HS [SKS] B932.12.1
Changed tapping cycle (not rigid) to G81, as per customer fax, MPK}
{4/4/96
Initial: Seikos M3 HS [SKS] B932.12.1
Created: Seikos M3 HS [SKS] B932.12.2
Undid my earlier change, added Cycle to drilling section, changed IF Tap? AND OpCyc1? to IF RigidTap?, MPK}
{1/21/98
Initial: Seikos M3 HS [SKS] B932.12.2
Created: Seicos Lamda 10M Bxxx.12
ForUser: Metric Precision & Machine & Eng., Inc.
Control: Hitachi Seiki Seicos Lamda 10M
Machine: Hitachi Seiki Seicos VM50
Develop: ComPost2 1.1b3, Virtual 4.21.21
Comment: New processor per fax and conversation with Bill Voelzke
Moved GetSpinOn to StrtPos line.
Moved CSAngleAB to line by itself after StrtPos line.
Changed M123 to IncValue OfstOff which outputs G91G30Z0
Deleted UnTool from end of program.
Added subs and calls AbsValueC, IncValueC and AbsOrIncC.
Updated per Fanuc 6M (FW) B001.12.08
Jim Radcliffe}
{Prog Numeric Format Definitions ****}
#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
{Prog Subroutines ****}
RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN
CalcCSWFO#:
DIV# ADD# ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') CS# Num#('5') Num#('6')
RETURN
Group#:
ADD# Trunc# CalcCSWFO# Num#('0')
RETURN
GValue#:
ADD# MUL# SUB# CalcCSWFO# Group# Num#('6') Num#('54')
RETURN
GroupValue#:
ADD# Group# Num#('-2')
RETURN
CSWFO:
'G' GValue#
IF LessThan? GroupValue# NUM#('0')
ELSE
GroupValue#
END
RETURN
WFO:
'G' ADD# PartNum# Num#('53')
RETURN
DoCSG52:
'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ#
RETURN
G52Stuff:
IF NOT MultipleParts?
IF NOT WFOCS?
IF ChangeCS?
SeqC DoCSG52 EOL
ELSE
IF NOT SameTool?
SeqC DoCSG52 EOL
END
END
END
ClearCSOffset
END
RETURN
WFOStuff:
IF Flag?('2')
IF WFOCS?
IF NOT SameTool?
CSWFO
ELSE
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is hadled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
ELSE
IF NOT SameTool?
WFO
END
END
SetFlagF('2')
END
RETURN
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN
DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' A' CSOffsetA# ' B' CSOffsetB# ' )' EOL
RETURN
DoCSG52Comment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN
OffsetComments:
IF NOT MultipleParts?
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
END
ELSE
IF ChangeCS?
DoCSG52Comment
ELSE
IF NOT SameTool?
DoCSG52Comment
END
END
END
END
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
OffsetComments
RETURN
AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN
IncValueC:
IF AbsValue?
IncValue
END
RETURN
AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN
CSAngleAB:
IF AAxisAvail? OR BAxisAvail?
'M70'
END
RETURN
CSAngleABC:
IF AChange? OR BChange?
CSAngleAB
END
RETURN
PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN
EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN
FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN
FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN
ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN
OpenMP:
NewProg
IF WorkFixtureOffsets?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
SeqC SubCall CallLab RepLab Parts EOL
StartSub
END
RETURN
DoCSWFOOps:
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CSWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN
DoCSG52Ops:
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC DoCSG52 EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN
CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
SeqC AbsOrIncC EOL
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN
SubCSMP:
IF WorkFixtureOffsets?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN
DoAbsOrInc:
IF Flag?('1') AND ZMove?
IncValueC
ELSE
AbsOrIncC
END
RETURN
DoDrillAbsOrInc:
IF Flag?('1') AND SPZMove?
IncValueC
ELSE
AbsOrIncC
END
RETURN
RestoreAbsOrInc:
IF Flag?('1')
SeqC AbsOrIncC EOL
END
RETURN
FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN
Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN
SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN
OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC
IF RigidTap?
'G841'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC 'G80' EOL
SeqC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
RETURN
GetSpinOn:
IF CoolOff?
SpinOn
ELSE
'M13'
END
RETURN
ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('2') {WFO needs to be output}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OptionalCycle1, OptCyc1 -' EOL
' will output a G84 Tapping Cycle, instead of G841 Rigid Direct Tapping.' EOL
END
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('66')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('66') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN
InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN
FirstOp1:
DoOpComments
Seq OpToolID ToolChng EOL
DoPostScript
G52Stuff
RETURN
FirstOp2:
CheckPass
SeqC AbsOrInc Rapid WFOStuff Plane StrtPos Speed PreTool GetSpinOn EOL
SeqC CSAngleAB EOL
RETURN
FirstOp3:
SeqC OfstOn EOL
RETURN
NewToolOp1:
SeqC IncValueC OfstOff EOL
RETURN
NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrIncC Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN
NewToolOp3: {Start new Operation}
DoOpComments
Seq OpToolID ToolChng EOL
DoPostScript
G52Stuff
RETURN
NewToolOp4:
CheckPass
SeqC AbsOrInc Rapid WFOStuff Plane StrtPos Speed PreTool GetSpinOn EOL
SeqC CSAngleABC EOL
RETURN
NewToolOp5:
SeqC OfstOn EOL
RETURN
SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC IncValueC OfstOff EOL
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? or ChangeCS?
SeqC IncValueC OfstOff EOL
END
END
RETURN
SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN
SameToolOp3: {Start new Operation}
G52Stuff
IF LAST ProgStop?
SeqC AbsOrInc Rapid WFOStuff PlaneC StrtPos SpeedC GetSpinOn EOL
SeqC CSAngleABC EOL
SeqC OfstOn EOL
ELSE
SeqC AbsOrInc Rapid WFOStuff PlaneC StrtPos SpeedC EOL
SeqC CSAngleABC EOL
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN
End1:
SeqC IncValueC OfstOff EOL
RETURN
End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC AbsOrIncC Rapid FirstHome EOL
END
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
CSAngleAB
END
EOL
IF ProgStop?
SeqC 'M0' EOL
END
RETURN
End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN
MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
SetFlagF('2')
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN
MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
SetFlagF('2')
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN
MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN
NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN
{Start of executable Prog, top level ****}
ProgStart {setup and initializations}
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
Wyszukiwarka
Podobne podstrony:
Fanuc 10M LH [BI] MZ41 12Fanuc 10M Kit C028 12Fanuc 10M [RE] CZ65 12 2dane MP dz pr 2 12 rok 2Seikos M2 HS [B&C] B517 12 09Fanuc 10M (AGA) M147 81 2248 12Fanuc 10M MVJr[G43r] M192 87Biuletyn 01 12 201412 control statementsRzym 5 w 12,14 CZY WIERZYSZ EWOLUCJIwięcej podobnych podstron