{Change Comments ***********************************************************}
{7/27/90
Copied & modified: GE 550 LeBlonde L080.56
For: Grand Valley
Machine: LeBlonde
Control: GE 550
Updated to Version 3.2 per Fanuc 10T MS [-] L001.70 Format
DWB}
{9/27/90
Copied & modified: GE 550 LeBlonde L080.70
For: Cad Cam DNC Machining, New Mexico
Machine: LeBlonde
Control: GE 550
Changed '%' to '=' on opening line of output.
Added Speed Table.
Added 'M42' for middle gear range that applies to Speed Table. Will need to add low and high.
Post is going to require special turret handling. This control has two turrets, but they are
not yet supported in this processor. Tom is going out there today to find out what we need to do.
DWB}
{10/30/90
Modified: GE 550 LeBlonde (CCD) L178.70
For: Cad Cam DNC Machining, New Mexico
Machine has 2 turrets, using ToolOver20?, also in the DoOpComments and in CheckOffset.
Tools over 20 are the rear turret. X's are - and arcs are reversed.
Tools not over 20 are the front turret. X's are + and arcs are standard.
Added GearRange in place of 'M42', also modified Speed codes for change over per Earnest.
Modified default format F to show all places after the decimal point. Changed ^####0 to ^00000
JR}
{7/15/91
Modified: GE 550 LeBlonde (CCD) L178.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
No Canned Cycles are supported.
DWB}
{9/25/91
Modified: GE 550 LeBlonde (CCD) L178.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
DWB}
{Prog Numeric Format Definitions *******************************************}
#1 = '#.00'
#2 = '####^###0;0'
#3 = '########;0'
#4 = '###^##0'
#5 = '####^0'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(FinishXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(ToolLess20#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)
{Prog Subroutines **********************************************************}
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
IF ToolOver20?
'( REAR TURRET TOOL ' ToolLess20# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
ELSE
'( FRONT TURRET TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
PSInit: {reset flags from last Op, .70}
RETURN
PSStuff:
RETURN
DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN
DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN
StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN
ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC StockOnNoCan XSPC FeedRate EOL
RETURN
IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqC StockOnNoCan XSPC FeedRate EOL
RETURN
FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
SeqC StockOnNoCan ZSPC FeedRate EOL
RETURN
Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Feed XCP ZCP RapidF EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Feed XOpCD ZCP RapidF EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Feed StockOnNoCan XSP StockOff ZCP RapidF EOL
FaceApproachSP
END
END
RETURN
CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
IF NOT NewGear?
SeqC SpinOn EOL
END
ELSE
IF NewGear?
SeqC SpinOff EOL
SeqC GearRange EOL
SeqC SpinOn EOL
END
END
IF NewToolOffset?
IF ToolOver20?
SeqC 'T1000' EOL
SeqC 'T10' LatheOffset EOL
ELSE
SeqC 'T0000' EOL
SeqC 'T00' LatheOffset EOL
END
END
SeqC Table(5001,SpeedRPM#,1) EOL
DoPostScript
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X2000' EOL
SeqC GearRange InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC FeedC MoveXC MoveZC
IF LAST ThreadFeat?
RapidF
END
RapidFC EOL
ELSE
IF LineFeat?
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
Feed
END
END
END
END
END
NEXTFeat
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsValue EOL
SeqC GearRange EOL
SeqC SpinOn EOL
SeqC 'T' {tool label}
IF ToolOver20?
'1' {1 specifies rear turret}
NegSideLathe
ReverseXZArcs
ELSE
'0' {0 specifies front turret}
PosSideLathe
StandardXZArcs
END
'0' LatheOffset EOL {0 means that the tool is in position}
SeqC Preset Home Table(5001,SpeedRPM#,1) EOL
Approach
ELSE
IF NewTool?
{Finish off last Operation}
StockOff {.62}
FeedC
IF LAST ApproachOD?
SeqC XCPC RapidFC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
END
END
SeqC ZCPC RapidFC EOL
DoEndOpPS
SeqC NewHome 'T' {Tool label}
IF LAST ToolOver20?
'1' {1 specifies rear turret}
ELSE
'0' {0 specifies front turret}
END
'0' {no indexing **if this is the last tool on this turret we need to put back to the 1st tool on this turret position}
'00' EOL {cancel offset}
SeqC SpinOff EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
':' EOL
{Start new Operation}
':' EOL
DoOpComments
DoPostScript
SeqC AbsValue EOL
SeqC GearRange EOL
SeqC SpinOn EOL
SeqC 'T' {Tool label}
IF ToolOver20?
'1' {1 specifies rear turret}
ToolLess20# {**Needs to be the number of indexes from the last tool used on this turret. 2 for each tool}
NegSideLathe
ReverseXZArcs
ELSE
'0' {0 specifies front turret}
Tool# {**Needs to be the number of indexes from the last tool used on this turret. 2 for each tool}
PosSideLathe
StandardXZArcs
END
LatheOffset EOL
Seq Preset Home Table(5001,SpeedRPM#,1) EOL
Approach
ELSE
IF SameTool? {.62}
{Start new Operation}
':' EOL
DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
SeqC FeedC StockOnNoCan XSPC ZSPC RapidFC EOL
ELSE
FeedC
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC RapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
SeqC ZCPC EOL
ELSE {LAST ApproachFace}
SeqC ZCPC RapidFC EOL
END
SeqC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC RapidFC EOL
SeqC ZCPC EOL
ELSE {LAST ApproachFace}
SeqC ZCPC RapidFC EOL
END
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC RapidFC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC RapidFC EOL
END
SeqC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Threading?
IF Taper?
SeqC
'X' ADD# FinishXRadius# MUL# Taper# NumSc#('1')
EOL
SeqC 'G33X' FinishXRadius# FinZ ThrdLead EOL
ELSE
SeqC 'X' FinishXRadius# EOL
SeqC 'G33' FinZ ThrdLead EOL
END
SeqC Feed XCSP RapidF EOL
SeqC ZCSP EOL
ELSE
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC FeedC StrtPos RapidFC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X2000' EOL
SeqC GearRange SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}
{End of program ************************************************************}
{finish last operation}
StockOff
FeedC
IF ApproachOD?
SeqC XCPC RapidFC EOL
ELSE
IF ApproachID?
SeqC XOpECDC RapidFC EOL
END
END
SeqC ZCPC RapidFC EOL
DoEndOpPS
SeqC FirstHome 'T' {Tool label}
IF ToolOver20?
'1' {1 specifies rear turret}
ELSE
'0' {0 specifies front turret}
END
'0' {no indexing ** we need to put the turret back to the 1st tools position}
'00' EOL {cancel offset}
SeqC SpinOff EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Wyszukiwarka
Podobne podstrony:
GE 550 LeBlonde [KSW] L219 82 8GE 550 LeBlond (HAC) L115 82GE 550 LeBlonde L080 82GE 1050T LeBlonde [CM] L249 82GE 1050 LeBlonde [DEW] L250 82GE 550 Okuma LS N L059 82 1GE 550 HNC [AMC] L246 82GE 102C Leblond [GV] L073 82 2GE 550T LeBlonde L082 82GE 550 L&S [GV] L293 82 3GE 550L LeBlonde L083 82GE 550L LeBlonde [R&R] L241 82GE 550 L&S L184 82 5GE 1050 LeBlonde Rgl L033 85GE 550 DeVlieg 4K M908 89GE 550 M087 87GE 550 MC [SN] NMU25 87 1GE 550 L&S [FC] L407 85GE 1050T LeBlonde L105 85 1więcej podobnych podstron